Name	adwaita-icon-theme
Description	GNOME standard icons
Version	49.0-1
Package Base	adwaita-icon-theme
Homepage	https://gitlab.gnome.org/GNOME/adwaita-icon-theme
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Jan de Groot <jgc@archlinux.org>', 'Lukas Fleischer <lfleischer@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/adwaita-icon-theme
Sources	['git+https://gitlab.gnome.org/GNOME/adwaita-icon-theme.git#tag=49.0']
Dependencies	['adwaita-cursors', 'adwaita-icon-theme-legacy', 'hicolor-icon-theme']
Optional-Dependencies	[]
Build-Dependencies	['git', 'gtk-update-icon-cache', 'meson']
Provides	[]
Builddate	13-09-2025 22:55:17
Architecture	any
Distro-Version
Licenses	['CC-BY-SA-3.0 OR LGPL-3.0-only']
Hash	0a65c18d218cf26a17547ee60913485b650db86588f8b25a98556b0fef30f214

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgbase=adwaita-icon-theme
pkgname=(
  adwaita-icon-theme
  adwaita-cursors
)
pkgver=49.0
pkgrel=1
pkgdesc="GNOME standard icons"
url="https://gitlab.gnome.org/GNOME/adwaita-icon-theme"
arch=(any)
license=("CC-BY-SA-3.0 OR LGPL-3.0-only")
depends=(
  adwaita-icon-theme-legacy
  hicolor-icon-theme
)
makedepends=(
  git
  gtk-update-icon-cache
  meson
)
source=("git+https://gitlab.gnome.org/GNOME/adwaita-icon-theme.git#tag=${pkgver/[a-z]/.&}")
b2sums=('aef30129fdfb8aa74cdd3de6662f0b10dfb6b87141a794f7b51d0c67834a0a863cb7e22a8b89388243296d77c0fa6b24cad3a6cc73d10c7a76e76c617c42be2f')

prepare() {
  cd $pkgbase
}

build() {
  arch-meson $pkgbase build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_adwaita-icon-theme() {
  depends+=(adwaita-cursors)

  meson install -C build --destdir "$pkgdir"

  # Split cursors
  mkdir -p cursors/usr/share/icons/Adwaita
  mv {"$pkgdir",cursors}/usr/share/icons/Adwaita/cursors

  # Covered by common licenses
  rm -r "$pkgdir/usr/share/licenses"
}

package_adwaita-cursors() {
  pkgdesc="GNOME standard cursors"
  depends=()

  mv cursors/* "$pkgdir"

  # deduplicate cursors
  hardlink -c "$pkgdir/usr"
}

# vim:set sw=2 sts=-1 et: