Name	archlinux-keyring
Description	Arch Linux PGP keyring
Version	20260206-1
Package Base	archlinux-keyring
Homepage	https://gitlab.archlinux.org/archlinux/archlinux-keyring/
Maintainers	['Christian Hesse <eworm@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Pierre Schmitz <pierre@archlinux.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/archlinux-keyring
Sources	['archlinux-keyring::git+https://gitlab.archlinux.org/archlinux/archlinux-keyring.git?signed#tag=20260206']
Dependencies	['pacman']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python', 'sequoia-sq', 'pkgconf', 'systemd', 'voa']
Provides	[]
Builddate	06-02-2026 09:34:57
Architecture	any
Distro-Version
Licenses	['GPL-3.0-or-later']
Hash	c3838da4ffa02fb11b243065f8863b8b3a562cdd32846033c50f5ee2d8603b44

# Maintainer: Christian Hesse <eworm@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgbase=archlinux-keyring
pkgname=(archlinux-keyring
         voa-verifiers-arch)
pkgver=20260206
pkgrel=1
pkgdesc='Arch Linux PGP keyring'
arch=('any')
url='https://gitlab.archlinux.org/archlinux/archlinux-keyring/'
license=('GPL-3.0-or-later')
makedepends=('git' 'python' 'sequoia-sq' 'pkgconf' 'systemd' 'voa')
checkdepends=('python-coverage' 'python-pytest')
source=("archlinux-keyring::git+https://gitlab.archlinux.org/archlinux/archlinux-keyring.git?signed#tag=${pkgver}")
sha256sums=('761d3f1c994cb8f859596f08134133332dbceccc67c16c236aa51fee8886ef91')
validpgpkeys=('02FD1C7A934E614545849F19A6234074498E9CEE'  # Christian Hesse <eworm@archlinux.org>
              '991F6E3F0765CF6295888586139B09DA5BF0D338'  # David Runge <dvzrv@archlinux.org>
              '5134EF9EAF65F95B6BB1608E50FB9B273A9D0BB5'  # Johannes Löthberg <demize@archlinux.org>
              'B4B759625D4633430B74877059E43E106B247368'  # Leonidas Spyropoulos <artafinde@archlinux.org>
              'E240B57E2C4630BA768E2F26FC1B547C8D8172C8'  # Levente Polyak <anthraxx@archlinux.org>
              'C100346676634E80C940FB9E9C02FF419FECBE16') # Morten Linderud <foxboron@archlinux.org>

build() {
  cd archlinux-keyring/

  make build build-voa
}

check() {
  cd archlinux-keyring/

  make check
}

package_archlinux-keyring() {
  install=$pkgname.install
  depends=('pacman')

  cd archlinux-keyring/

  make PREFIX='/usr' DESTDIR="${pkgdir}" install
}

package_voa-verifiers-arch() {
  pkgdesc='Arch Linux verifiers for the Hierarchy for the Verification of OS Artifacts (VOA)'

  cd archlinux-keyring/

  make PREFIX='/usr' DESTDIR="${pkgdir}" install-voa
}