Name	bash-completion
Description	Programmable completion for the bash shell
Version	2.17.0-3
Package Base	bash-completion
Homepage	https://github.com/scop/bash-completion
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Eric Bélanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/bash-completion
Sources	['https://github.com/scop/bash-completion/releases/download/2.17.0/bash-completion-2.17.0.tar.xz']
Dependencies	['bash']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	21-01-2026 18:58:14
Architecture	any
Distro-Version
Licenses	['GPL-2.0-only']
Hash	d4857ba0bdfa56323265d27113797031f8c73490c4658cba6d5e348e1d929a91

# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=bash-completion
pkgver=2.17.0
pkgrel=3
pkgdesc='Programmable completion for the bash shell'
arch=(any)
url='https://github.com/scop/bash-completion'
license=(GPL-2.0-only)
depends=(bash)
options=(!emptydirs !makeflags)
backup=('etc/bash_completion.d/000_bash_completion_compat.bash')
source=($url/releases/download/$pkgver/$pkgname-$pkgver.tar.xz)
validpgpkeys=(A558062B6D5DA1347CD468D52B0AE2C1B09B07CB)
b2sums=('ee11f2bff82b0852979e4843c7ad5e5b976e4d1e44ab5ed1b96da64fe9b32d91150f12f32bf7c6c0286cd2a0c424d786bbad47066403c71f8d3c8425487427dd')

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # bash-completion is sourced in /etc/bash.bashrc so that non-bash shell don't source it
  rm "${pkgdir}/etc/profile.d/bash_completion.sh"

  # remove Slackware's makepkg completion
  rm "${pkgdir}/usr/share/bash-completion/completions/makepkg"

  # checksec 3.1.0-2 ships its own
  rm "${pkgdir}/usr/share/bash-completion/completions/checksec"

  # patchutils 0.4.4-1 ships its own
  rm "${pkgdir}/usr/share/bash-completion/completions/interdiff"
}