Name	mailcap
Description	Helper application and MIME type associations for file types
Version	2.1.54-2
Package Base	mailcap
Homepage	https://pagure.io/mailcap
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>', 'T.J. Townsend <blakkheim@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/mailcap
Sources	['git+https://pagure.io/mailcap#commit=9699055a1b4dfb90f7594ee2e8dda705fa56d3b8']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['mime-types']
Builddate	13-07-2024 00:23:28
Architecture	any
Distro-Version
Licenses	['MIT']
Hash	58bc925ece87ae2f00560f785ff5dbfb799c08596e0f15f74cd7cce928399640

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=mailcap
pkgver=2.1.54
pkgrel=2
pkgdesc="Helper application and MIME type associations for file types"
url="https://pagure.io/mailcap"
arch=(any)
license=(MIT)
makedepends=(git)
checkdepends=(python)
provides=(mime-types)
conflicts=(mime-types)
replaces=(mime-types)
backup=(
  etc/mailcap
  etc/mime.types
  etc/nginx/mime.types
)
_commit=9699055a1b4dfb90f7594ee2e8dda705fa56d3b8  # tags/r2-1-54
source=("git+https://pagure.io/mailcap#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd mailcap
  git describe --tags | sed 's/^r//;s/-/./;s/-/./;s/-/+/g'
}

build() {
  cd mailcap
  make
}

check() {
  cd mailcap
  make check
}

package() {
  cd mailcap
  make DESTDIR="$pkgdir" install
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
}

# vim:set sw=2 sts=-1 et: