Name	opengl-man-pages
Description	OpenGL Man Pages - OpenGL 4.x
Version	20240713-2
Package Base	opengl-man-pages
Homepage	https://github.com/KhronosGroup/OpenGL-Refpages
Maintainers	['AndyRTR <andyrtr@archlinux.org>', 'Sven-Hendrik Haase <svenstaro@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/opengl-man-pages
Sources	['license-from-upstream', 'opengl-man-pages::git+https://github.com/KhronosGroup/OpenGL-Refpages#commit=9813a5569411cad5250d719a9efed2fac732e56f']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['docbook5-xml', 'docbook-xsl', 'libxslt', 'docbook-mathml', 'w3c-mathml2', 'python', 'git']
Provides	[]
Builddate	14-06-2025 01:26:06
Architecture	any
Distro-Version
Licenses	['OPL-1.0', 'SGI-B-2.0']
Hash	442daca0f918ca0d26d4938e8317e6ea72908ab3739db88b78f5d8e1f8e865d1

# Maintainer: AndyRTR <andyrtr@archlinux.org>

pkgname=opengl-man-pages
pkgver=20240713
_commit=9813a5569411cad5250d719a9efed2fac732e56f
pkgrel=2
pkgdesc="OpenGL Man Pages - OpenGL 4.x"
arch=('any')
url="https://github.com/KhronosGroup/OpenGL-Refpages"
license=('SGI-B-2.0' 'OPL-1.0')
makedepends=('docbook5-xml' 'docbook-xsl' 'libxslt' 'docbook-mathml' 'w3c-mathml2' 'python' 'git')
source=(${pkgname}::git+https://github.com/KhronosGroup/OpenGL-Refpages#commit=$_commit
        'license-from-upstream')
sha256sums=('848033ced8fb614dd10cff688dcff878d4758544c654a541a72f362f1746b49e'
            'a7b2f6669d7ead91dcaf5a03620cdf9d37c54d83fd1899b4ef84683c7e6d4024')

build() {
  for manpages in gl4; do
    cd "${srcdir}/${pkgname}/${manpages}"
      for file in *.xml; do
        xsltproc --xinclude --noout --nonet /usr/share/xml/docbook/xsl-stylesheets/manpages/docbook.xsl ${file}
      done
  done
}

package() {
  install -d "${pkgdir}/usr/share/man/man3"
  for manpages in gl4; do
    cd "${srcdir}/${pkgname}/${manpages}"
    install -m644 *.3G "${pkgdir}/usr/share/man/man3/"
  done
  # license
  install -D -m644 "${srcdir}/license-from-upstream" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}