Name	pacman-mirrorlist
Description	Arch Linux mirror list for use by pacman
Version	20260213-1
Package Base	pacman-mirrorlist
Homepage	https://www.archlinux.org/mirrorlist/
Maintainers	['Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Dan McGee <dan@archlinux.org>', 'Florian Pritz <bluewind@xinu.at>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/pacman-mirrorlist
Sources	['mirrorlist']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	13-02-2026 20:33:59
Architecture	any
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	c0db04b0cb9a55e4723fc6df385f528388460d6b89af2f131efb80918c2d55ae

# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Dan McGee <dan@archlinux.org>

pkgname=pacman-mirrorlist
pkgver=20260213
pkgrel=1
pkgdesc="Arch Linux mirror list for use by pacman"
arch=('any')
url="https://www.archlinux.org/mirrorlist/"
license=('GPL-2.0-or-later')
backup=(etc/pacman.d/mirrorlist)
source=(mirrorlist)
b2sums=('f3dccc2bb650a3c250e083aac1975b21838a28bb7fce5f55161182e4bf9177bfbcda85b004d5fe0eb9bb7d6030f18ebab0b6a24dc5168dce0ad1ea58ce4cbe3f')

# NOTE on building this package:
# * Run bash -c ". PKGBUILD; updatelist"
# * Update the checksums, update pkgver
# * Build the package

updatelist() {
  # cleanup first
  rm -f mirrorlist
  # get a full list (sorted)
  curl -o mirrorlist.all 'https://archlinux.org/mirrorlist/?country=all'
  # get a list of working mirrors (unsorted)
  curl -o mirrorlist.checked 'https://archlinux.org/mirrorlist/?country=all&protocol=https&ip_version=4&ip_version=6&use_mirror_status=on'
  # write new sorted list
  while IFS= read -r line; do
      grep -q "$line" mirrorlist.checked && echo "$line" >> mirrorlist
  done < mirrorlist.all
  # cleanup
  rm -f mirrorlist.{all,checked}
}

package() {
  mkdir -p "$pkgdir/etc/pacman.d"
  install -m0644 "$srcdir/mirrorlist" "$pkgdir/etc/pacman.d/"
}