Name	psutils
Description	A set of postscript utilities
Version	3.3.14-2
Package Base	psutils
Homepage	https://github.com/rrthomas/psutils
Maintainers	['Caleb Maclennan <caleb@alerque.com>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	['Ronald van Haren <ronald.archlinux.org>', 'Tom Newsom <Jeepster@gmx.co.uk>', 'eric <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/psutils
Sources	['https://github.com/rrthomas/psutils/releases/download/v3.3.14/psutils-3.3.14.tar.gz']
Dependencies	['libpaper', 'python', 'python-puremagic', 'python-pypdf']
Optional-Dependencies	[]
Build-Dependencies	['python-build', 'python-installer', 'python-wheel', 'python-argparse-manpage', 'python-setuptools']
Provides	[]
Builddate	17-12-2025 11:30:02
Architecture	any
Distro-Version
Licenses	['GPL-3.0-only']
Hash	e7668e5ad1adfc9016fca51f25d776df086f0b45854d3fa2770bbc49c8d6d15f

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: eric <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
 
pkgname=psutils
pkgver=3.3.14
pkgrel=2
pkgdesc='A set of postscript utilities'
arch=(any)
url="https://github.com/rrthomas/$pkgname"
license=(GPL-3.0-only)
depends=(libpaper
         python
         python-puremagic
         python-pypdf)
makedepends=(python-{build,installer,wheel}
             python-argparse-manpage
             python-setuptools)
checkdepends=(ghostscript
              python-pytest-datafiles
              python-wand)
_archive="$pkgname-$pkgver"
source=("$url/releases/download/v$pkgver/$_archive.tar.gz")
sha256sums=('6212167dd8c09f59c9535d5e416c4f8c01431b7a5beab0ee68f4ec416ca3980c')

build() {
	cd "$_archive"
	python -m build -wn
}

check() {
	cd "$_archive"
	export PYTHONPATH="."
	pytest
}

package() {
	cd "$_archive"
	python -m installer -d "$pkgdir" dist/*.whl
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYING
}