Name	python-attrs
Description	Attributes without boilerplate.
Version	25.4.0-3
Package Base	python-attrs
Homepage	https://www.attrs.org
Maintainers	['Carl Smedstad <carsme@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-attrs
Sources	['git+https://github.com/python-attrs/attrs.git#tag=25.4.0']
Dependencies	['python']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python-build', 'python-hatch-fancy-pypi-readme', 'python-hatch-vcs', 'python-hatchling', 'python-installer']
Provides	[]
Builddate	15-12-2025 18:05:16
Architecture	any
Distro-Version
Licenses	['MIT']
Hash	4a95df5b417da63feb46651177256dca2d7db35b79a87bca1b5b249b97c7a59c

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=python-attrs
pkgver=25.4.0
pkgrel=3
pkgdesc="Attributes without boilerplate."
arch=('any')
license=('MIT')
url="https://www.attrs.org"
depends=('python')
makedepends=(
  'git'
  'python-build'
  'python-hatch-fancy-pypi-readme'
  'python-hatch-vcs'
  'python-hatchling'
  'python-installer'
)
checkdepends=(
  'python-cloudpickle'
  'python-hypothesis'
  'python-pytest'
  'python-zope-interface'
)
source=("git+https://github.com/python-attrs/attrs.git#tag=$pkgver")
sha512sums=('8e15f9dbd7ffcb56413dec8b1318b9f7e9ccd4425af6579e9283048caff123eb3ed20e1afc1c16335db47832933d4e3f5239cc5c1472e8201d977391249bfa28')

build() {
  cd ${pkgname#python-}
  python -m build --wheel --no-isolatio
}

check() {
  cd ${pkgname#python-}
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest
}

package() {
  cd ${pkgname#python-}
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}