Name	python-chardet
Description	Python3 module for character encoding auto-detection
Version	5.2.0-7
Package Base	python-chardet
Homepage	https://github.com/chardet/chardet
Maintainers	['George Rawlinson <grawlinson@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	['Felix Yan <felixonmars@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>', 'William Rea <sillywilly@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-chardet
Sources	['python-chardet::git+https://github.com/chardet/chardet#tag=6.0.0.post1']
Dependencies	['python']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python-build', 'python-installer', 'python-hatchling', 'python-hatch-vcs']
Provides	[]
Builddate	14-12-2025 12:55:19
Architecture	any
Distro-Version
Licenses	['LGPL']
Hash	315f0e3c09c100b9b40bb2a8ba5a69bdd4d00ef5b16fd82e3a6e28dd91850ba0

# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=python-chardet
pkgver=6.0.0.post1
pkgrel=1
pkgdesc='Universal encoding detector for Python'
arch=(any)
url='https://chardet.readthedocs.io/'
license=(LGPL-2.1-or-later)
depends=(python)
makedepends=(
  git
  python-build
  python-installer
  python-hatchling
  python-hatch-vcs
)
checkdepends=(
  python-pytest
  python-pytest-timeout
  python-pytest-xdist
  python-hypothesis
)
source=("$pkgname::git+https://github.com/chardet/chardet#tag=$pkgver")
sha512sums=('f0e45eaa9eb4ee619f593140c895a6fc2318d16dfe1ec6fe6f2113355a1d170f301ae850306f12d44a9ced8a7747be9a1d75e2359a830d9de9a0d42914a29f82')
b2sums=('5aa0f7f3da193a551c8bde0ee70199c071f303436170b4d962295518086a62bc915b2836f986539d7f9d2bd818333a5718786c963710643242d37d5e90306831')

build() {
  cd "$pkgname"

  python -m build --wheel --no-isolation
}

check() {
  cd "$pkgname"

  pytest -v
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl
}