Name	python-idna
Description	Internationalized Domain Names in Applications (IDNA)
Version	3.11-2
Package Base	python-idna
Homepage	https://github.com/kjd/idna
Maintainers	['Felix Yan <felixonmars@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-idna
Sources	['git+https://github.com/kjd/idna.git#tag=v3.11']
Dependencies	['python']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python-build', 'python-installer', 'python-flit-core']
Provides	[]
Builddate	14-12-2025 12:45:53
Architecture	any
Distro-Version
Licenses	['BSD-3-Clause']
Hash	8f0eaf1e1a840613cea97c8e88bc77d17e99c0dc4001316f0bbb3f533770cb67

# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=python-idna
pkgver=3.11
pkgrel=2
pkgdesc="Internationalized Domain Names in Applications (IDNA)"
arch=('any')
license=('BSD-3-Clause')
url="https://github.com/kjd/idna"
depends=('python')
makedepends=('git' 'python-build' 'python-installer' 'python-flit-core')
checkdepends=('python-pytest')
source=("git+https://github.com/kjd/idna.git#tag=v$pkgver")
sha512sums=('abe8aaf9d19326701e749fb13eaabe9f2562ed7e7e8e1a5efeec01e402a956ed2951aa79059196ee585ee1cca127bd4aa91f8cd8b6e1458aaddd01d2ab9ecd9d')

build() {
   cd idna
   python -m build --no-isolation --wheel
}

check() {
   cd idna
   pytest
}

package() {
   cd idna
   python -m installer --destdir="$pkgdir" dist/*.whl
   install -Dm644 LICENSE.md -t "$pkgdir"/usr/share/licenses/$pkgname/
}