Name	python-jaraco.functools
Description	Functools like those found in stdlib
Version	4.1.0-3
Package Base	python-jaraco.functools
Homepage	https://github.com/jaraco/jaraco.functools
Maintainers	['Chih-Hsuan Yen <yan12125@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	['Kyle Keen <keenerd@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-jaraco.functools
Sources	['git+https://github.com/jaraco/jaraco.functools?signed#tag=v4.1.0']
Dependencies	['python', 'python-more-itertools']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python-build', 'python-installer', 'python-setuptools-scm', 'python-wheel']
Provides	[]
Builddate	14-12-2025 16:08:08
Architecture	any
Distro-Version
Licenses	['MIT']
Hash	b6fde8d3fef8e1338d92aa59c85b3179e4d35a67029b123a74ee23f62bd86344

# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Contributor: Kyle Keen <keenerd@gmail.com>

pkgname=python-jaraco.functools
# https://github.com/jaraco/jaraco.functools/blob/main/NEWS.rst
pkgver=4.1.0
pkgrel=3
pkgdesc='Functools like those found in stdlib'
arch=('any')
url='https://github.com/jaraco/jaraco.functools'
license=('MIT')
depends=('python' 'python-more-itertools')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools-scm' 'python-wheel')
checkdepends=('python-pytest' 'python-jaraco.classes')
conflicts=('python-jaraco')
replaces=('python-jaraco')
source=("git+https://github.com/jaraco/jaraco.functools?signed#tag=v$pkgver")
sha512sums=('a607327042760c23abc26f2213fc6c39abb6f9bbce1d58b0c8ac24c0cfda38cb954b1abdd43deb6535092e35325730d7d75b48047cc06be588f29335e93b4372')
validpgpkeys=(
  'CE380CF3044959B8F377DA03708E6CB181B4C47E' # https://github.com/jaraco.gpg
)

build() {
  cd jaraco.functools
  python -m build --wheel --no-isolation
}

check() {
  cd jaraco.functools
  pytest
}

package() {
  cd jaraco.functools
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}