Name	python-libevdev
Description	Python wrapper for libevdev
Version	0.11-6
Package Base	python-libevdev
Homepage	https://gitlab.freedesktop.org/libevdev/python-libevdev
Maintainers	['Filipe Laíns (FFY00) <lains@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-libevdev
Sources	['https://gitlab.freedesktop.org/libevdev/python-libevdev/-/archive/0.11/python-libevdev-0.11.tar.gz']
Dependencies	['libevdev', 'python']
Optional-Dependencies	[]
Build-Dependencies	['python-setuptools', 'python-sphinx', 'python-sphinx_rtd_theme']
Provides	[]
Builddate	14-12-2025 20:32:06
Architecture	any
Distro-Version
Licenses	['MIT']
Hash	4430da25c951556eb01a8294b6f89292946f64430fc6deebd867ad9d9985c636

# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>

pkgname=python-libevdev
pkgver=0.11
pkgrel=6
arch=('any')
url='https://gitlab.freedesktop.org/libevdev/python-libevdev'
license=('MIT')
pkgdesc='Python wrapper for libevdev'
depends=('python' 'libevdev')
makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx_rtd_theme')
checkdepends=('python-pytest' 'python-pluggy')
source=("$url/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('224e2d18915f08d9f02e32845968e0e2eac531ad7f4efe5401de692cdb0980049f3cfd9cb869319e7526dbefd38144ab6e0b52ceba67ab371045ce60d21286da')

prepare() {
  cd $pkgname-$pkgver

  # This config-line makes 'make doc' fail.
  sed -i '/intersphinx_mapping/d' doc/source/conf.py
}

build() {
  cd $pkgname-$pkgver

  python setup.py build

  make doc
}

check() {
  cd $pkgname-$pkgver

  PYTHONPATH=. pytest test/*.py
}

package() {
  cd $pkgname-$pkgver

  python setup.py install --root "$pkgdir" --skip-build -O1

  # Install documentation
  install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  cp -r -a --no-preserve=ownership doc/html "$pkgdir"/usr/share/doc/$pkgname
  install -D -m644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  rm -rf "$pkgdir"/usr/share/doc/$pkgname/html/.doctrees
}