Name	python-platformdirs
Description	A library to determine platform-specific system directories
Version	4.9.3-1
Package Base	python-platformdirs
Homepage	https://github.com/tox-dev/platformdirs
Maintainers	['George Rawlinson <grawlinson@archlinux.org>']
Contributors	['Felix Yan <felixonmars@archlinux.org>', 'Tobias Roettger <toroettg@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-platformdirs
Sources	['python-platformdirs::git+https://github.com/tox-dev/platformdirs#tag=4.9.3']
Dependencies	['python']
Optional-Dependencies	[]
Build-Dependencies	['git', 'python-build', 'python-installer', 'python-hatchling', 'python-hatch-vcs']
Provides	[]
Builddate	24-02-2026 00:41:43
Architecture	any
Distro-Version
Licenses	['MIT']
Hash	63f56afef9d06bd06d71322e0f17748856715a082229aebb66121e398fba4d5c

# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Tobias Roettger <toroettg@gmail.com>

pkgname=python-platformdirs
pkgver=4.9.3
pkgrel=1
pkgdesc='A library to determine platform-specific system directories'
arch=(any)
url='https://github.com/tox-dev/platformdirs'
license=(MIT)
depends=(python)
makedepends=(
  git
  python-build
  python-installer
  python-hatchling
  python-hatch-vcs
)
checkdepends=(
  python-pytest
  python-pytest-mock
  python-appdirs
)
source=("$pkgname::git+$url#tag=$pkgver")
sha512sums=('7a9a9f24f3f1081300fc1d1ec2391ab61edb00c0b72ab6c8bea096733d39bcf94d08379cbb43c11756bc850ebfbc3881f3a08e679bd45bde7d0d42722f4a369f')
b2sums=('f2894476a44bbb648abbdb8297e8e71c7348993bac63966ee39f52d915e5d37dff6917f08e1897547f4e8087e31ad50e5eda438119482e6d3622bcbbaca9a241')

build() {
  cd "$pkgname"

  python -m build --wheel --no-isolation
}

check() {
  cd "$pkgname"

  PYTHONPATH="$(pwd)/src" pytest -v
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}