Name	python-pyudev
Description	Python bindings to libudev
Version	0.24.4-1
Package Base	python-pyudev
Homepage	https://github.com/pyudev/pyudev
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Filipe Laíns (FFY00) <lains@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>', 'Dwight Schauer <dschauer@ti.com>', 'Sebastian Wiesner <lunaryorn googlemail com>', 'examon <examon.mail[at]gmail[dot]com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/python-pyudev
Sources	['pyudev-0.24.4.tar.gz::https://github.com/pyudev/pyudev/archive/v0.24.4.tar.gz']
Dependencies	['systemd']
Optional-Dependencies	['python-wxpython']
Build-Dependencies	['python-build', 'python-installer', 'python-setuptools', 'python-wheel', 'python-sphinx']
Provides	[]
Builddate	11-02-2026 22:49:25
Architecture	any
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	068bb5f9beefde78878f2401d56e5b0eb6072830b61320dce653567768a710a1

# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: examon <examon.mail[at]gmail[dot]com>
# Contributor: Sebastian Wiesner <lunaryorn googlemail com>
# Contributor: Dwight Schauer <dschauer@ti.com>

_pkgname=pyudev
pkgname=python-$_pkgname
pkgver=0.24.4
pkgrel=1
arch=('any')
url='https://github.com/pyudev/pyudev'
license=('LGPL-2.1-or-later')
pkgdesc='Python bindings to libudev'
depends=('systemd')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel' 'python-sphinx')
checkdepends=('python-pytest' 'python-docutils' 'python-hypothesis' 'python-pip')
optdepends=('python-wxpython: WX integration')
source=("$_pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('d0edd89a9b024fd166d6286920a37baac5a739f89101a6d7c4dca3dad0b6d8d4a61e93c0ef1ca3795a677558579bdfecf49a5d5b61837345eed90a31fed4aa20')

prepare() {
  cd $_pkgname-$pkgver

  # Remove failing tests (we can't test udev inside makepkg)
  rm tests/test_{util,discover,device,monitor,enumerate,observer}.py

  # Fix documentation build
  sed -i "s|os.path.join(doc_directory, os.pardir)|os.path.join(doc_directory, os.pardir, 'src')|
          s|b'autodoc-process-docstring'|'autodoc-process-docstring'|" doc/conf.py
}

build() {
  cd $_pkgname-$pkgver

  python -m build -nw

  # Generate documentation
  sphinx-apidoc -f -e -o doc src/pyudev
  sphinx-build -a -b html doc doc/html
}

check() {
  cd $_pkgname-$pkgver

  PYTHONPATH=src python -m pytest
}

package() {
  cd $_pkgname-$pkgver

  python -m installer -d "$pkgdir" dist/*.whl

  # Install documentation
  install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  cp -r -a --no-preserve=ownership doc/html "$pkgdir"/usr/share/doc/$pkgname
  rm -rf "$pkgdir"/usr/share/doc/$pkgname/html/.doctrees
}