Name	qt5-translations
Description	A cross-platform application and UI framework (Translations)
Version	5.15.18-1
Package Base	qt5-translations
Homepage	https://www.qt.io
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/qt5-translations
Sources	['kde-qttranslations::git+https://invent.kde.org/qt/qt/qttranslations#commit=3cbcceb8e3e2e63a4022f1be946c7118c527a83e']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['git', 'qt5-tools']
Provides	[]
Builddate	02-11-2025 00:22:33
Architecture	any
Distro-Version
Licenses	['FDL', 'GPL3', 'LGPL3', 'custom']
Hash	1b8ebeed235e2585f394120e3d66563c27f99c4c41c28cc0eb57508b6d0ccda8

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=qt5-translations
_basever=5.15.18
pkgver=5.15.18
pkgrel=1
_commit=3cbcceb8e3e2e63a4022f1be946c7118c527a83e
arch=('any')
url='https://www.qt.io'
license=('GPL3' 'LGPL3' 'FDL' 'custom')
pkgdesc='A cross-platform application and UI framework (Translations)'
depends=()
makedepends=('git' 'qt5-tools')
groups=('qt5')
_pkgfqn=${pkgname/5-/}
source=(kde-$_pkgfqn::git+https://invent.kde.org/qt/qt/$_pkgfqn#commit=$_commit)
sha256sums=('d15d7ad365748ffc33fa655fdaab0b3fb7a6a1e6f8292886653a2fc7f66fd9d4')

pkgver() {
  cd kde-$_pkgfqn
  echo "$_basever+kde+r"`git rev-list --count v$_basever-lts-lgpl..$_commit` | sed -e 's|+kde+r0||'
}

prepare() {
  mkdir -p build
}

build() {
  cd build

  qmake ../kde-$_pkgfqn
  make
}

package() {
  cd build
  make INSTALL_ROOT="$pkgdir" install

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
}