Name	qt6-translations
Description	A cross-platform application and UI framework (Translations)
Version	6.10.2-1
Package Base	qt6-translations
Homepage	https://www.qt.io
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Felix Yan <felixonmars@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/qt6-translations
Sources	['git+https://code.qt.io/qt/qttranslations#tag=v6.10.2']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'git', 'ninja', 'qt6-tools']
Provides	[]
Builddate	29-01-2026 10:51:05
Architecture	any
Distro-Version
Licenses	['GPL-3.0-only', 'LGPL-3.0-only', 'LicenseRef-Qt-Commercial', 'Qt-GPL-exception-1.0']
Hash	8b3bfec2785364e1627023d7cdb420456ba06876da55eafa08cc3b41ec8d3249

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=qt6-translations
_pkgver=6.10.2
pkgver=${_pkgver/-/}
pkgrel=1
arch=(any)
url='https://www.qt.io'
license=(GPL-3.0-only
         LGPL-3.0-only
         LicenseRef-Qt-Commercial
         Qt-GPL-exception-1.0)
pkgdesc='A cross-platform application and UI framework (Translations)'
depends=()
makedepends=(cmake
             git
             ninja
             qt6-tools)
groups=(qt6)
_pkgfn=${pkgname/6-/}
source=(git+https://code.qt.io/qt/$_pkgfn#tag=v$_pkgver)
sha256sums=('7181898a85d46af66595cb00dc59453e59501dd49495ca8c0e8ad5b149c31191')

build() {
  export PATH="/usr/lib/qt6/bin:$PATH"
  cmake -B build -S $_pkgfn -G Ninja \
    -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  cmake --build build -j1
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
}