Name	xkeyboard-config
Description	X keyboard configuration files
Version	2.46-1
Package Base	xkeyboard-config
Homepage	https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/xkeyboard-config
Sources	['https://xorg.freedesktop.org/archive/individual/data/xkeyboard-config/xkeyboard-config-2.47.tar.xz', 'https://xorg.freedesktop.org/archive/individual/data/xkeyboard-config/xkeyboard-config-2.47.tar.xz.sig']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['xorg-xkbcomp', 'libxslt', 'python', 'meson']
Provides	['xkbdata']
Builddate	06-10-2025 13:16:12
Architecture	any
Distro-Version
Licenses	['LicenseRef-xkeyboard-config']
Hash	bb05062525f80ac6975f403470644af840ff294e0ddc526d645afa6caa44e18d

# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgname=xkeyboard-config
pkgver=2.47
pkgrel=1
pkgdesc="X keyboard configuration files"
arch=(any)
license=('LicenseRef-xkeyboard-config')
url="https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config"
makedepends=('xorg-xkbcomp' 'libxslt' 'python' 'meson') # 'git')
checkdepends=('python-pytest' 'python-pytest-xdist' 'libxkbcommon')
provides=('xkbdata')
replaces=('xkbdata')
conflicts=('xkbdata')
# https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config
source=(https://xorg.freedesktop.org/archive/individual/data/${pkgname}/${pkgname}-${pkgver}.tar.xz{,.sig})
sha256sums=('e59984416a72d58b46a52bfec1b1361aa7d84354628227ee2783626c7a6db6b6'
            'SKIP')
validpgpkeys=('FFB4CCD275AAA422F5F9808E0661D98FC933A145') # Sergey Udaltsov <sergey.udaltsov@gmail.com>

build() {
  arch-meson ${pkgname}-${pkgver} build \
    -D compat-rules=true \
    -D xorg-rules-symlinks=true

  # Print config
  meson configure build

  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}
 
package() {
  DESTDIR="$pkgdir" ninja -C build install
  install -m755 -d "${pkgdir}/var/lib/xkb"
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname-$pkgver/COPYING
}