Name	abseil-cpp
Description	Collection of C++ library code designed to augment the C++ standard library
Version	20250814.1-1
Package Base	abseil-cpp
Homepage	https://abseil.io
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'Massimiliano Torromeo <massimiliano.torromeo@gmail.com>']
Contributors	['Aleksandar Trifunović <akstrfn@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/abseil-cpp
Sources	['https://github.com/abseil/abseil-cpp/archive/20250814.1/abseil-cpp-20250814.1.tar.gz', 'scoped-mock-log.patch']
Dependencies	['gcc-libs', 'glibc', 'gtest']
Optional-Dependencies	[]
Build-Dependencies	['cmake']
Provides	[]
Builddate	22-09-2025 21:18:55
Architecture	x86_64
Distro-Version
Licenses	['Apache-2.0']
Hash	466313af41985fd11f13cee938f30a7341da195f37d0597fe7a1abe8f3c4fb29

# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Maintainer: Christian Heusel <gromit@archlinux.org>
# Contributor: Aleksandar Trifunović <akstrfn at gmail dot com>

pkgname=abseil-cpp
pkgver=20250814.1
pkgrel=1
pkgdesc="Collection of C++ library code designed to augment the C++ standard library"
arch=('x86_64')
url='https://abseil.io'
license=('Apache-2.0')
depends=('glibc' 'gtest' 'libgcc' 'libstdc++')
makedepends=('cmake')
source=("https://github.com/abseil/abseil-cpp/archive/$pkgver/$pkgname-$pkgver.tar.gz"
         scoped-mock-log.patch)
sha256sums=('1692f77d1739bacf3f94337188b78583cf09bab7e420d2dc6c5605a4f86785a1'
            'a6cbc612a2b96fcbd52d081e03e8581107ceb4827edb19d96510a31c568e1396')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -p1 -i ../scoped-mock-log.patch # Install target needed by protobuf
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  cmake -Bbuild \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_CXX_STANDARD=17 \
    -DBUILD_SHARED_LIBS=ON \
    -DABSL_BUILD_TEST_HELPERS=ON \
    -DABSL_USE_EXTERNAL_GOOGLETEST=ON \
    -DABSL_FIND_GOOGLETEST=ON \
    -DABSL_BUILD_TESTING=ON
  cd build
  cmake --build . --target all
}

check() {
  cd "$srcdir/$pkgname-$pkgver/build"
  ctest
}

package() {
  cd "$srcdir/$pkgname-$pkgver/build"
  DESTDIR="$pkgdir" cmake --install .
}