Name	acl
Description	Access control list utilities, libraries and headers
Version	2.3.2-1
Package Base	acl
Homepage	https://savannah.nongnu.org/projects/acl
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Thomas Bächler <thomas@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/acl
Sources	['git+https://git.savannah.nongnu.org/git/acl.git#tag=v2.3.2?signed']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['attr', 'git']
Provides	['xfsacl', 'libacl.so']
Builddate	24-01-2024 09:57:20
Architecture	x86_64
Distro-Version
Licenses	['LGPL']
Hash	cbfb71e8ba9aca9e51cbdfd77d0ec51371eb865a9a098c77e2c6046962e6ae0a

# Maintainer: Thomas Bächler <thomas@archlinux.org>

pkgname=acl
pkgver=2.3.2
pkgrel=1
pkgdesc='Access control list utilities, libraries and headers'
arch=('x86_64')
url='https://savannah.nongnu.org/projects/acl'
license=('LGPL-2.1-or-later AND GPL-2.0-or-later')
depends=('glibc')
makedepends=('attr' 'git')
provides=('libacl.so')
validpgpkeys=('600CD204FBCEA418BD2CA74F154343260542DF34'  # Brandon Philips <brandon@ifup.co>
              'B902B5271325F892AC251AD441633B9FE837F581'  # Frysinger <vapier@gentoo.org>
              '259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>
source=("git+https://git.savannah.nongnu.org/git/${pkgname}.git#tag=v${pkgver}?signed")
sha256sums=('1b4ad9a0d4a04275f5710184dd7a6fa7ffccadc33a3a4b4af43a8b7f9771a7da')

prepare() {
  cd $pkgname

  ./autogen.sh
}

build() {
  cd $pkgname

  ./configure \
    --libdir=/usr/lib \
    --libexecdir=/usr/lib \
    --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname

  make -k check
}

package() {
  cd $pkgname

  make DESTDIR="${pkgdir}" install
}