Name	alsa-lib
Description	An alternative implementation of Linux sound support
Version	1.2.15.3-2
Package Base	alsa-lib
Homepage	https://www.alsa-project.org
Maintainers	['David Runge <dvzrv@archlinux.org>']
Contributors	['judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/alsa-lib
Sources	['https://www.alsa-project.org/files/pub/lib/alsa-lib-1.2.15.3.tar.bz2', 'https://www.alsa-project.org/files/pub/lib/alsa-lib-1.2.15.3.tar.bz2.sig']
Dependencies	['alsa-topology-conf', 'alsa-ucm-conf', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	['libasound.so', 'libatopology.so']
Builddate	16-01-2026 12:50:28
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	f72ac3d448f7fe4c64142daaf40083414afff75229f4ec84c384f8d0ba09b077

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=alsa-lib
pkgver=1.2.15.3
pkgrel=2
pkgdesc="An alternative implementation of Linux sound support"
arch=(x86_64)
url="https://www.alsa-project.org"
license=(LGPL-2.1-or-later)
depends=(
  alsa-topology-conf
  alsa-ucm-conf
  glibc
)
provides=(
  libasound.so
  libatopology.so
)
install=$pkgname.install
source=(
  $url/files/pub/lib/$pkgname-$pkgver.tar.bz2{,.sig}
)
sha512sums=('7fc0fa8a5ae02d3404d2c262c6a14fcbb8b08e25993eac86b9e89b8419ed4d293b422da77b3eb7a1930f26c316b638e5aa7bdba78b0ada9908b0362d132a0cc0'
            'SKIP')
b2sums=('13c21ad3686ed5a8dfa48e8fa8e1b6f3f9a138aeaef2ba778838a8c6f9cbe209a5ece0d9953e2dcdd1e5b90ce50409e77b9485010689adfe4aed176cb8774c0e'
        'SKIP')
validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release@alsa-project.org>

prepare() {
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
  # -flto=auto is not supported: https://github.com/alsa-project/alsa-lib/issues/110
  CFLAGS+=" -flto-partition=none"
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --without-debug
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  export LD_LIBRARY_PATH="$pkgname-$pkgver/src/.libs/:$LD_LIBRARY_PATH"
  make -k check -C $pkgname-$pkgver
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgver/{MEMORY-LEAK,TODO,NOTES,ChangeLog,doc/asoundrc.txt} -t "$pkgdir/usr/share/doc/$pkgname/"
}