Name	at-spi2-core
Description	Protocol definitions and daemon for D-Bus at-spi
Version	2.58.3-1
Package Base	at-spi2-core
Homepage	https://gitlab.gnome.org/GNOME/at-spi2-core
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/at-spi2-core
Sources	['git+https://gitlab.gnome.org/GNOME/at-spi2-core.git?signed#tag=2.58.3']
Dependencies	['bash', 'dbus', 'gcc-libs', 'glib2', 'glibc', 'gsettings-desktop-schemas', 'libx11', 'libxi', 'libxtst', 'systemd-libs', 'xorg-xprop']
Optional-Dependencies	[]
Build-Dependencies	['dbus-broker', 'gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'libxml2', 'meson', 'python-sphinx']
Provides	['at-spi2-atk', 'atk', 'libatk-1.0.so', 'libatk-bridge-2.0.so', 'libatspi.so']
Builddate	03-01-2026 15:26:32
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	c4d18b391bf322ae7b53ff18cbb3ac58bf2dd9f07f39083e65a5973e2ec8349b

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=at-spi2-core
pkgname=(
  at-spi2-core
  at-spi2-core-docs
)
pkgver=2.58.3
pkgrel=1
pkgdesc="Protocol definitions and daemon for D-Bus at-spi"
url="https://gitlab.gnome.org/GNOME/at-spi2-core"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  bash
  dbus
  gcc-libs
  glib2
  glibc
  gsettings-desktop-schemas
  libx11
  libxi
  libxtst
  systemd-libs
  xorg-xprop
)
makedepends=(
  dbus-broker
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  libxml2
  meson
  python-sphinx
)
checkdepends=(
  at-spi2-core
)
source=("git+https://gitlab.gnome.org/GNOME/at-spi2-core.git?signed#tag=$pkgver")
b2sums=('17558b4c2b712ae638cbfa1ca70bf9baeede797b9167a701f63cfc1941b4b332382ee5658f637f7757c7c7416e945b3b3452d8af55661268a784b70c90071e80')
validpgpkeys=(
  276BFDAFB36212F8DB095E2140823A056FD6D4B3 # Mike Gorse <mgorse@suse.com>
)

prepare() {
  cd at-spi2-core
}

build() {
  local meson_options=(
    -D default_bus=dbus-broker
    -D docs=true
    -D gtk2_atk_adaptor=false
  )

  arch-meson at-spi2-core build "${meson_options[@]}"
  meson compile -C build
}

check() {
  dbus-run-session meson test -C build --print-errorlogs
}

package_at-spi2-core() {
  provides=(
    "at-spi2-atk=$pkgver-$pkgrel"
    "atk=$pkgver-$pkgrel"
    libatk-1.0.so
    libatk-bridge-2.0.so
    libatspi.so
  )
  conflicts=(
    'at-spi2-atk<=2.38.0-2'
    'atk<=2.38.0-2'
  )
  replaces=(
    'at-spi2-atk<=2.38.0-2'
    'atk<=2.38.0-2'
  )

  meson install -C build --destdir "$pkgdir"

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_at-spi2-core-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: