Name	bison
Description	The GNU general-purpose parser generator
Version	3.8.2-8
Package Base	bison
Homepage	https://www.gnu.org/software/bison/bison.html
Maintainers	['Lukas Fleischer <lfleischer@archlinux.org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'Eric Belanger <eric@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/bison
Sources	['https://ftp.gnu.org/gnu/bison/bison-3.8.2.tar.xz', 'https://ftp.gnu.org/gnu/bison/bison-3.8.2.tar.xz.sig']
Dependencies	['gettext', 'glibc', 'm4', 'sh']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	08-09-2024 17:27:20
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-or-later']
Hash	417f8e94f7088e6de69cd36d7927d82988266f298e8d4fed3166abb13e971941

# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>

pkgname=bison
pkgver=3.8.2
pkgrel=8
pkgdesc="The GNU general-purpose parser generator"
arch=('x86_64')
license=('GPL-3.0-or-later')
url="https://www.gnu.org/software/bison/bison.html"
depends=(
  gettext
  glibc
  m4
  sh
)
source=(
  "https://ftp.gnu.org/gnu/bison/${pkgname}-${pkgver}.tar.xz"{,.sig}
  glr2.patch
)
b2sums=('e211b61494c911f55b72a8b70b5a48cdf4000ce9e675a1f1f52735bb8f57d93a3f8075341451263af9c9c531004907ae2b62b1873e7e4664c2cd26fa3b12271c'
        'SKIP'
        'c1e0ad2b8be4a1499b158d6126b015f7c9ec9817a482ff3ff0463776d908052ee344e5995f6cf7fc52606932f848f9b26333239a5b9d46158cbc886622c65aaf')
validpgpkeys=('7DF84374B1EE1F9764BBE25D0DDCAA3278D5264E')  # Akim Demaille

prepare() {
  cd "${pkgname}-${pkgver}"
  patch -Np1 -i ../glr2.patch
}

build() {
  cd "${pkgname}-${pkgver}"

  CFLAGS+=' -ffat-lto-objects' \
  ./configure --prefix=/usr --datadir=/usr/share
  make
}

check() {
  cd "${pkgname}-${pkgver}"
  make check
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}