Name	boost-libs
Description	Free peer-reviewed portable C++ source libraries (runtime libraries)
Version	1.89.0-4
Package Base	boost
Homepage	https://www.boost.org/
Maintainers	['Christian Heusel <gromit@archlinux.org>', 'Evangelos Foutras <foutrelis@archlinux.org>', 'Jelle van der Waa <jelle@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Giovanni Scafora <giovanni@archlinux.org>', 'Ionut Biru <ibiru@archlinux.org>', 'Kritoke <kritoke@gamebox.net>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>', 'Luca Roccia <little_rock@users.sourceforge.net>', 'Marius Knaust <marius.knaust@gmail.com>', 'Stéphane Gaudreault <stephane@archlinux.org>', 'kevin <kevin@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/boost
Sources	['https://archives.boost.io/release/1.89.0/source/boost_1_89_0.tar.bz2', 'https://github.com/boostorg/range/commit/9ac89e99.patch']
Dependencies	['bzip2', 'icu', 'zlib', 'zstd']
Optional-Dependencies	['openmpi']
Build-Dependencies	['icu', 'python', 'python-numpy', 'bzip2', 'zlib', 'openmpi', 'zstd']
Provides	['libboost_atomic.so', 'libboost_charconv.so', 'libboost_chrono.so', 'libboost_cobalt.so', 'libboost_container.so', 'libboost_context.so', 'libboost_contract.so', 'libboost_coroutine.so', 'libboost_date_time.so', 'libboost_fiber.so', 'libboost_filesystem.so', 'libboost_graph.so', 'libboost_graph_parallel.so', 'libboost_iostreams.so', 'libboost_json.so', 'libboost_locale.so', 'libboost_log.so', 'libboost_log_setup.so', 'libboost_math_c99.so', 'libboost_math_c99f.so', 'libboost_math_c99l.so', 'libboost_math_tr1.so', 'libboost_math_tr1f.so', 'libboost_math_tr1l.so', 'libboost_mpi.so', 'libboost_mpi_python314.so', 'libboost_nowide.so', 'libboost_numpy314.so', 'libboost_prg_exec_monitor.so', 'libboost_process.so', 'libboost_program_options.so', 'libboost_python314.so', 'libboost_random.so', 'libboost_regex.so', 'libboost_serialization.so', 'libboost_stacktrace_addr2line.so', 'libboost_stacktrace_basic.so', 'libboost_stacktrace_from_exception.so', 'libboost_stacktrace_noop.so', 'libboost_thread.so', 'libboost_timer.so', 'libboost_type_erasure.so', 'libboost_unit_test_framework.so', 'libboost_url.so', 'libboost_wave.so', 'libboost_wserialization.so']
Builddate	14-12-2025 18:22:21
Architecture	x86_64
Distro-Version
Licenses	['BSL-1.0']
Hash	a7067af89ef140940e5df9c9e81a49fdfa4f8f7e7d4c5cc2a4ab64d9d63fd043

# Maintainer: Evangelos Foutras <foutrelis@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Marius Knaust <marius.knaust@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Kritoke <kritoke@gamebox.net>
# Contributor: Luca Roccia <little_rock@users.sourceforge.net>

pkgname=('boost' 'boost-libs')
pkgver=1.89.0
pkgrel=4
_srcname=boost_${pkgver//./_}
pkgdesc="Free peer-reviewed portable C++ source libraries"
arch=('x86_64')
url="https://www.boost.org/"
license=('BSL-1.0')
makedepends=('icu' 'python' 'python-numpy' 'bzip2' 'zlib' 'openmpi' 'zstd')
source=(https://archives.boost.io/release/$pkgver/source/$_srcname.tar.bz2
        https://github.com/boostorg/range/commit/9ac89e99.patch)
sha256sums=('85a33fa22621b4f314f8e85e1a5e2a9363d22e4f4992925d4bb3bc631b5a0c7a'
            'd66116e9ed03c309e5338cfa12b624894d116aed0903595842d97d461db70a28')

prepare() {
  # Add missing include
  patch -d $_srcname/boost -p3 < 9ac89e99.patch
}

build() {
  local JOBS="$(sed 's/.*\(-j *[0-9]\+\).*/\1/' <<<$MAKEFLAGS)"
  local python_version=$(
    python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')

  pushd $_srcname/tools/build
  ./bootstrap.sh --cxxflags="$CXXFLAGS $LDFLAGS"
  ./b2 install --prefix="$srcdir"/fakeinstall
  ln -s b2 "$srcdir"/fakeinstall/bin/bjam
  popd

  cd $_srcname
  ./bootstrap.sh --with-toolset=gcc --with-icu --with-python=python3

  # support for OpenMPI
  echo "using mpi ;" >>project-config.jam

  # boostbook is needed by quickbook
  install -dm755 "$srcdir"/fakeinstall/share/boostbook
  cp -a tools/boostbook/{xsl,dtd} "$srcdir"/fakeinstall/share/boostbook/

  # install to $srcdir/fakeinstall in preparation for split packaging
  ./b2 install \
    variant=release \
    debug-symbols=off \
    threading=multi \
    runtime-link=shared \
    link=shared,static \
    toolset=gcc \
    cxxstd=23 \
    python=$python_version \
    cflags="$CPPFLAGS $CFLAGS -fPIC -O3 -ffat-lto-objects" \
    cxxflags="$CPPFLAGS $CXXFLAGS -fPIC -O3 -ffat-lto-objects" \
    linkflags="$LDFLAGS" \
    --layout=system \
    $JOBS \
    \
    --prefix="$srcdir"/fakeinstall
}

package_boost() {
  local python_version=$(
    python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')

  pkgdesc+=' (development headers)'
  optdepends=('python: for python bindings')
  options=('staticlibs')

  install -d "$pkgdir"/usr/lib
  cp -a fakeinstall/lib/*.{a,so} "$pkgdir"/usr/lib/
  cp -a fakeinstall/lib/cmake "$pkgdir"/usr/lib/
  cp -a fakeinstall/{bin,include,share} "$pkgdir"/usr/

  # https://github.com/boostorg/python/issues/203#issuecomment-391477685
  for _lib in python numpy; do
    ln -srL "$pkgdir"/usr/lib/libboost_${_lib}{${python_version/.},${python_version%.*}}.so
  done
}

package_boost-libs() {
  local python_version=$(
    python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')

  pkgdesc+=' (runtime libraries)'
  depends=('bzip2' 'zlib' 'icu' 'zstd')
  optdepends=('openmpi: for mpi support')
  provides=(
    libboost_atomic.so
    libboost_charconv.so
    libboost_chrono.so
    libboost_cobalt.so
    libboost_container.so
    libboost_context.so
    libboost_contract.so
    libboost_coroutine.so
    libboost_date_time.so
    libboost_fiber.so
    libboost_filesystem.so
    libboost_graph.so
    libboost_graph_parallel.so
    libboost_iostreams.so
    libboost_json.so
    libboost_locale.so
    libboost_log.so
    libboost_log_setup.so
    libboost_math_c99.so
    libboost_math_c99f.so
    libboost_math_c99l.so
    libboost_math_tr1.so
    libboost_math_tr1f.so
    libboost_math_tr1l.so
    libboost_mpi{,_python${python_version/.}}.so
    libboost_nowide.so
    libboost_numpy${python_version/.}.so
    libboost_prg_exec_monitor.so
    libboost_process.so
    libboost_program_options.so
    libboost_python${python_version/.}.so
    libboost_random.so
    libboost_regex.so
    libboost_serialization.so
    libboost_stacktrace_addr2line.so
    libboost_stacktrace_basic.so
    libboost_stacktrace_from_exception.so
    libboost_stacktrace_noop.so
    libboost_thread.so
    libboost_timer.so
    libboost_type_erasure.so
    libboost_unit_test_framework.so
    libboost_url.so
    libboost_wave.so
    libboost_wserialization.so
  )

  install -dm755 "$pkgdir"/usr/lib
  cp -a fakeinstall/lib/*.so.* "$pkgdir"/usr/lib/

  # https://github.com/boostorg/mpi/issues/112
  local site_packages=$(python -c 'import site; print(site.getsitepackages()[0])')
  install -d "$pkgdir"$site_packages/boost
  touch "$pkgdir"$site_packages/boost/__init__.py
  python -m compileall -o 0 -o 1 -o 2 "$pkgdir"$site_packages/boost
  cp fakeinstall/lib/boost-python*/mpi.so "$pkgdir"$site_packages/boost/mpi.so
}

# vim:set ts=2 sw=2 et: