Name	bubblewrap
Description	Unprivileged sandboxing tool
Version	0.11.0-1
Package Base	bubblewrap
Homepage	https://github.com/containers/bubblewrap
Maintainers	['Jan Alexander Steffens (heftig) <heftig@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/bubblewrap
Sources	['git+https://github.com/containers/bubblewrap?signed#tag=v0.11.0']
Dependencies	['gcc-libs', 'glibc', 'libcap']
Optional-Dependencies	[]
Build-Dependencies	['bash-completion', 'docbook-xsl', 'git', 'libxslt', 'meson']
Provides	[]
Builddate	30-10-2024 22:18:35
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-or-later']
Hash	2200c96efe46a6f78f85d55d0f4da03b4627dbb8635750b5be1194f073c78934

# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgbase=bubblewrap
pkgname=(
  bubblewrap
  bubblewrap-suid
)
pkgver=0.11.0
pkgrel=1
pkgdesc='Unprivileged sandboxing tool'
url='https://github.com/containers/bubblewrap'
arch=(x86_64)
license=(LGPL-2.0-or-later)
depends=(
  gcc-libs
  glibc
  libcap
)
makedepends=(
  bash-completion
  docbook-xsl
  git
  libxslt
  meson
)
source=("git+$url?signed#tag=v$pkgver")
b2sums=('dd5ac8fcffdf71a9bd10b765ae113424b1dea740fcdbf99cbd7716b6c33121ec2a987d8cf186eccc17a2e67dfa82ce4f843301c7d33a9007e3702d52c3312017')
validpgpkeys=(
  DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90 # Simon McVittie <smcv@collabora.com>
)

prepare() {
  cd $pkgbase
}

build() {
  arch-meson $pkgbase build -D selinux=disabled
  meson compile -C build
}

check() {
  # Broken in our containers
  meson test -C build --print-errorlogs || :
}

package_bubblewrap() {
  meson install -C build --destdir "$pkgdir"
}

package_bubblewrap-suid() {
  pkgdesc+=" (setuid variant)"
  provides=("bubblewrap=$pkgver-$pkgrel")
  conflicts=(bubblewrap)

  meson install -C build --destdir "$pkgdir"
  chmod u+s "$pkgdir/usr/bin/bwrap"
}

# vim:set sw=2 sts=-1 et: