Name	ccid
Description	A generic USB Chip/Smart Card Interface Devices driver
Version	1.7.1-1
Package Base	ccid
Homepage	https://ccid.apdu.fr/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Giovanni Scafora <giovanni@archlinux.org>']
Contributors	['Daniel Plaza <daniel.plaza.espi@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/ccid
Sources	['https://ccid.apdu.fr/files/ccid-1.7.1.tar.xz', 'https://ccid.apdu.fr/files/ccid-1.7.1.tar.xz.asc']
Dependencies	['flex', 'libusb', 'pcsclite']
Optional-Dependencies	[]
Build-Dependencies	['meson']
Provides	[]
Builddate	05-02-2026 07:49:10
Architecture	x86_64
Distro-Version
Licenses	['GPL', 'LGPL']
Hash	b6876ccac99294b0ab394f5a0502d7a0d3dd18017486638fa568023f719c0e2b

# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Daniel Plaza <daniel.plaza.espi@gmail.com>

pkgname=ccid
pkgver=1.7.1
pkgrel=1
pkgdesc='A generic USB Chip/Smart Card Interface Devices driver'
arch=('x86_64')
url='https://ccid.apdu.fr/'
license=('LGPL' 'GPL')
depends=('pcsclite' 'libusb' 'flex')
makedepends=('meson')
backup=('etc/reader.conf.d/libccidtwin')
validpgpkeys=('F5E11B9FFE911146F41D953D78A1B4DFE8F9C57E') # Ludovic Rousseau <ludovic.rousseau@free.fr>
source=("https://ccid.apdu.fr/files/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha256sums=('32799ab16fe6e493c9452be3823f21810fbe80b884021a6f6f3fa69f26be5c86'
            'SKIP')

build() {
  arch-meson "${pkgname}-${pkgver}" build \
    -Dclass=true \
    -Dserial=true
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"

  install -D -m0644 "${pkgname}-${pkgver}/src/92_pcscd_ccid.rules" "${pkgdir}/usr/lib/udev/rules.d/92_pcscd_ccid.rules"
}