Name	cryptsetup
Description	Userspace setup tool for transparent encryption of block devices using dm-crypt
Version	2.8.4-1
Package Base	cryptsetup
Homepage	https://gitlab.com/cryptsetup/cryptsetup/
Maintainers	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Christian Hesse <eworm@archlinux.org>']
Contributors	['Thomas Bächler <thomas@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/cryptsetup
Sources	['https://www.kernel.org/pub/linux/utils/cryptsetup/v2.8/cryptsetup-2.8.4.tar.sign', 'https://www.kernel.org/pub/linux/utils/cryptsetup/v2.8/cryptsetup-2.8.4.tar.xz']
Dependencies	['device-mapper', 'glibc', 'json-c', 'libblkid.so', 'libcrypto.so', 'libdevmapper.so', 'libjson-c.so', 'libuuid.so', 'openssl', 'popt', 'util-linux-libs']
Optional-Dependencies	[]
Build-Dependencies	['util-linux', 'asciidoctor']
Provides	['libcryptsetup.so']
Builddate	27-01-2026 16:27:52
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	af0c3758d595b8f918b47f8ee2367dfa9e2da20dbdca4035e2c063e1ffb93d3e

# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Thomas Bächler <thomas@archlinux.org>

pkgname=cryptsetup
pkgver=2.8.4
pkgrel=1
pkgdesc='Userspace setup tool for transparent encryption of block devices using dm-crypt'
arch=('x86_64')
license=('GPL-2.0-or-later')
url='https://gitlab.com/cryptsetup/cryptsetup/'
depends=('device-mapper' 'libdevmapper.so'
         'glibc'
         'openssl' 'libcrypto.so'
         'popt'
         'util-linux-libs' 'libblkid.so' 'libuuid.so'
         'json-c' 'libjson-c.so')
makedepends=('util-linux' 'asciidoctor')
checkdepends=('jq' 'procps-ng' 'xxd')
conflicts=('mkinitcpio<38-1')
provides=('libcryptsetup.so')
options=('!emptydirs')
validpgpkeys=('2A2918243FDE46648D0686F9D9B0577BD93E98FC') # Milan Broz <gmazyland@gmail.com>
source=("https://www.kernel.org/pub/linux/utils/cryptsetup/v${pkgver%.*}/${pkgname}-${pkgver}.tar."{xz,sign})
sha256sums=('443e46f8964c9acc780f455afbb8e23aa0e8ed7ec504cfc59e04f406fa1e8a83'
            'SKIP')

build() {
  cd "${srcdir}"/$pkgname-${pkgver}

  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --disable-ssh-token \
    --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd "${srcdir}"/$pkgname-${pkgver}
  make check
}

package() {
  cd "${srcdir}"/$pkgname-${pkgver}

  make DESTDIR="${pkgdir}" install

  # install docs
  install -D -m0644 -t "${pkgdir}"/usr/share/doc/cryptsetup/ FAQ.md docs/{Keyring,LUKS2-locking}.txt
}