Name	diffutils
Description	Utility programs used for creating patch files
Version	3.12-2
Package Base	diffutils
Homepage	https://www.gnu.org/software/diffutils
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Sébastien Luttringer <seblu@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'Andreas Radke <andyrtr@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/diffutils
Sources	['git+https://git.savannah.gnu.org/git/diffutils.git#tag=v3.12?signed', 'git+https://git.savannah.gnu.org/git/gnulib.git', 'https://ftp.gnu.org/gnu/diffutils/diffutils-3.12.tar.gz', 'https://ftp.gnu.org/gnu/diffutils/diffutils-3.12.tar.gz.sig']
Dependencies	['bash', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'gperf', 'help2man', 'python', 'wget']
Provides	[]
Builddate	27-04-2025 00:06:06
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-or-later']
Hash	53830e09d46ceccde48a0fc1dcee026902e2a639a1b8a5e2a091d2a9d90b6967

# Maintainer: Sébastien Luttringer <seblu@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>

pkgname=diffutils
pkgver=3.12
pkgrel=2
pkgdesc='Utility programs used for creating patch files'
arch=('x86_64')
url='https://www.gnu.org/software/diffutils'
license=('GPL-3.0-or-later')
depends=('glibc')
makedepends=('git' 'gperf' 'help2man' 'python' 'wget')
validpgpkeys=('155D3FC500C834486D1EEA677FD9FCCB000BEEEE') # Jim Meyering <meyering@meta.com>
source=("git+https://git.savannah.gnu.org/git/diffutils.git#tag=v${pkgver}?signed"
        "git+https://git.savannah.gnu.org/git/gnulib.git"
        "https://ftp.gnu.org/gnu/diffutils/diffutils-${pkgver}.tar.gz"{,.sig})
b2sums=('d7e72109db2b1607c2d17253df9232555d0dd3a87a2d1a1f90fac4ecdc4035a538c08078c741eea987eb37b0ab8c772553abddbc986fbeeda186fff7d2ff31da'
        'SKIP'
        '3c1c75257d919ae08e279ea33ccde0b537d9d9a9e48a4ac73e691cc48877b69281361a9ad18ca4b8a9ffa02030d1fdd6b25bd5c0d3c81779d14f279b1bab5834'
        'SKIP')

prepare() {
  cd "${pkgname}"

  git submodule init
  git config submodule.gnulib.url "${srcdir}/gnulib"
  git -c protocol.file.allow=always submodule update

  ./bootstrap \
    --skip-po
}

build() {
  cd "${pkgname}"

  ./configure \
    --prefix=/usr \
    --disable-gcc-warnings
  make

  # Generate diffutils mo files from dist tarball
  cd "${srcdir}/${pkgname}-${pkgver}/po"
  for po in *.po; do
    msgfmt "${po}" -o "${po%.po}.mo"
  done
}

check() {
  cd "${pkgname}"

  make check
}

package() {
  cd "${pkgname}"

  make DESTDIR="$pkgdir" install

  # Install diffutils mo files from dist tarball
  cd "${srcdir}/${pkgname}-${pkgver}/po"
  for mo in *.mo; do
    install -Dm 644 "${mo}" "${pkgdir}/usr/share/locale/${mo%.mo}/LC_MESSAGES/${pkgname}.mo"
  done
}

# vim:set ts=2 sw=2 et: