Name	ed
Description	A POSIX-compliant line-oriented text editor
Version	1.22.4-1
Package Base	ed
Homepage	https://www.gnu.org/software/ed/ed.html
Maintainers	['Caleb Maclennan <alerque@archlinux.org>', 'Caleb Maclennan <caleb@alerque.com>']
Contributors	['Andreas Radke <andyrtr@archlinux.org>', 'Dave Reisner <dreisner@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/ed
Sources	['https://ftp.gnu.org/gnu/ed/ed-1.22.4.tar.lz', 'https://ftp.gnu.org/gnu/ed/ed-1.22.4.tar.lz.sig']
Dependencies	['glibc', 'sh']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	03-01-2026 21:14:27
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-only']
Hash	31f60d1fcfb582d729d44e8ee1d64a75ec6da36a3c32ee9d2af4ea5859d83579

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>

pkgname=ed
pkgver=1.22.4
pkgrel=1
pkgdesc='A POSIX-compliant line-oriented text editor'
arch=(x86_64)
license=(GPL-2.0-only)
url="https://www.gnu.org/software/ed/ed.html"
depends=(glibc
         sh)
options=(!emptydirs)
_archive="$pkgname-$pkgver"
source=("https://ftp.gnu.org/gnu/ed/$_archive.tar.lz"{,.sig})
sha256sums=('987a1ebbbad3fcf63a1ffa9e29b3fa7de065150d16319d0a49dd8b57f81d3e9c'
            'SKIP')
validpgpkeys=('1D41C14B272A2219A739FA4F8FE99503132D7742') # Antonio Diaz Diaz

build() {
	cd "$_archive"
	./configure \
		--prefix=/\
		--bindir=/usr/bin \
		--mandir=/usr/share/man \
		--infodir=/usr/share/info \
		"CPPFLAGS=$CPPFLAGS" \
		"CFLAGS=$CFLAGS" \
		"LDFLAGS=$LDFLAGS"
	make
}

check() {
	make -C "$_archive" check
}

package() {
	make -C "$_archive" "DESTDIR=$pkgdir" install
}