Name	efivar
Description	Tools and libraries to work with EFI variables
Version	39-1
Package Base	efivar
Homepage	https://github.com/rhboot/efivar
Maintainers	['David Runge <dvzrv@archlinux.org>']
Contributors	['Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>', 'Tobias Powalowski <tpowa@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/efivar
Sources	['git+https://github.com/rhboot/efivar#tag=a77a4ffec000ad5dfc5d6394d208784672acda82?signed']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	['git', 'mandoc']
Provides	['libefiboot.so', 'libefisec.so', 'libefivar.so']
Builddate	01-02-2024 10:57:25
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	16422088da42f1ac562851d06ce86ad659f0775c86d9b1f54fa5a7067f9d636a

# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>

pkgname=efivar
pkgdesc="Tools and libraries to work with EFI variables"
pkgver=39
_commit=a77a4ffec000ad5dfc5d6394d208784672acda82  # refs/tags/39
pkgrel=1
arch=(x86_64)
url="https://github.com/rhboot/efivar"
license=(LGPL-2.1-or-later)
depends=(glibc)
makedepends=(
  git
  mandoc
)
checkdepends=(grub)
provides=(
  libefiboot.so
  libefisec.so
  libefivar.so
)
source=(
  "git+$url#tag=$_commit?signed"
)
sha512sums=('SKIP')
b2sums=('SKIP')
validpgpkeys=('B00B48BC731AA8840FED9FB0EED266B70F4FEF10') # Peter Jones <pjones@redhat.com>

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  # disable -Werror by default by setting ERRORS to empty string
  make ERRORS='' all -C $pkgname
}

check() {
  make GRUB_PREFIX=grub test -k -j1 -C $pkgname
}

package() {
  local make_options=(
    V=1
    DESTDIR="$pkgdir/"
    libdir=/usr/lib/
    bindir=/usr/bin/
    mandir=/usr/share/man/
    includedir=/usr/include/
    install
    -j1
    -C $pkgname
  )

  make "${make_options[@]}"
  install -vDm 644 $pkgname/{README.md,TODO} -t "$pkgdir/usr/share/doc/$pkgname/"
}