Name	enchant
Description	A wrapper library for generic spell checking
Version	2.8.14-1
Package Base	enchant
Homepage	https://rrthomas.github.io/enchant/
Maintainers	['Felix Yan <felixonmars@gmail.com>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Andrea Scarpino <andrea@archlinux.org>', 'dorphell <dorphell@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/enchant
Sources	['git+https://git.savannah.gnu.org/git/gnulib.git', 'git+https://github.com/gnulib-modules/bootstrap.git', 'git+https://github.com/rrthomas/enchant#tag=v2.8.14']
Dependencies	['gcc-libs', 'glib2', 'glibc']
Optional-Dependencies	['aspell', 'hspell', 'hunspell', 'libvoikko', 'nuspell']
Build-Dependencies	['aspell', 'git', 'hspell', 'hunspell', 'libvoikko', 'nuspell', 'vala']
Provides	['libenchant-2.so']
Builddate	18-12-2025 01:05:21
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	c6763494121f8f493c87ada9d98cd6b250398df64f321d670558b3c390041144

# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=enchant
pkgver=2.8.14
pkgrel=1
pkgdesc="A wrapper library for generic spell checking"
url="https://rrthomas.github.io/enchant/"
arch=('x86_64')
license=('LGPL-2.1-or-later')
depends=(
  'gcc-libs'
  'glib2'
  'glibc'
)
makedepends=(
  'aspell'
  'git'
  'hspell'
  'hunspell'
  'libvoikko'
  'nuspell'
  'vala'
)
checkdepends=('unittestpp')
optdepends=(
  'aspell: for aspell based spell checking support'
  'hspell: for hspell based spell checking support'
  'hunspell: for hunspell based spell checking support'
  'libvoikko: for libvoikko based spell checking support'
  'nuspell: for nuspell based spell checking support'
)
provides=('libenchant-2.so')
source=(
  "git+https://github.com/rrthomas/enchant#tag=v$pkgver"
  "git+https://git.savannah.gnu.org/git/gnulib.git"
  "git+https://github.com/gnulib-modules/bootstrap.git"
)
b2sums=('2c039b03153ede4f0b66c1150e8bc5a0637b764f6d325cb20d67167416de5ddd82fd9642b943b6691bec0f0d2b6155751ac20cbf46d3e6b3249f8b0d7b67f10d'
        'SKIP'
        'SKIP')

prepare() {
  cd enchant

  git submodule init
  git submodule set-url gnulib "$srcdir/gnulib"
  git submodule set-url gl-mod/bootstrap "$srcdir/bootstrap"
  git -c protocol.file.allow=always -c protocol.allow=never submodule update

  ./bootstrap
}

build() {
  local configure_options=(
    --prefix=/usr
    --sysconfdir=/etc
    --localstatedir=/var
    --disable-static
    --enable-relocatable
  )

  cd enchant
  ./configure "${configure_options[@]}"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd enchant
  make check
}

package() {
  cd enchant
  make DESTDIR="$pkgdir" install
}