Name	evince
Description	Document viewer (PDF, PostScript, XPS, djvu, dvi, tiff, cbr, cbz, cb7, cbt)
Version	1:48.1-1
Package Base	evince
Homepage	https://apps.gnome.org/Evince
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/evince
Sources	['git+https://gitlab.gnome.org/GNOME/evince.git?signed#tag=48.1']
Dependencies	['at-spi2-core', 'cairo', 'dconf', 'djvulibre', 'exempi', 'gcc-libs', 'gdk-pixbuf2', 'glib2', 'glibc', 'gnome-desktop', 'gsettings-desktop-schemas', 'gsfonts', 'gspell', 'gst-plugins-base-libs', 'gstreamer', 'gtk3', 'gvfs', 'hicolor-icon-theme', 'libarchive', 'libgxps', 'libhandy', 'libsecret', 'libspectre', 'libsynctex', 'libtiff', 'libxml2', 'pango', 'poppler-glib']
Optional-Dependencies	['texlive-bin']
Build-Dependencies	['appstream', 'gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'meson', 'texlive-bin', 'yelp-tools']
Provides	['libevdocument3.so', 'libevview3.so']
Builddate	19-09-2025 02:02:54
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-or-later']
Hash	22b7a76277110fbcc6649f7febe73fcdbf40e200fc03546a23a6ab0455d88be8

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgbase=evince
pkgname=(
  evince
  evince-lib-docs
)
pkgver=48.1
pkgrel=1
epoch=1
pkgdesc="Document viewer (PDF, PostScript, XPS, djvu, dvi, tiff, cbr, cbz, cb7, cbt)"
url="https://gitlab.gnome.org/GNOME/evince"
arch=(x86_64)
license=(GPL-2.0-or-later)
depends=(
  at-spi2-core
  cairo
  dconf
  djvulibre
  exempi
  gcc-libs
  gdk-pixbuf2
  glib2
  glibc
  gnome-desktop
  gsettings-desktop-schemas
  gsfonts
  gspell
  gst-plugins-base-libs
  gstreamer
  gtk3
  gvfs
  hicolor-icon-theme
  libarchive
  libgxps
  libhandy
  libsecret
  libspectre
  libsynctex
  libtiff
  libxml2
  pango
  poppler-glib
)
makedepends=(
  appstream
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  texlive-bin
  yelp-tools
)
source=(
  "git+https://gitlab.gnome.org/GNOME/evince.git?signed#tag=${pkgver/[a-z]/.&}"
)
b2sums=('11f4b758c97251804dbd3eb0e8b3716b6340292186730e3e4e6ac5fe758524be7912ca5e32cd0fce932be67a1c6394bcaf3dcdc05eb0aa06f7158ae31673d55c')
validpgpkeys=(
  3289FDCF12AC2321BB41E9EF342B349ED9FE78F0 # Germán Poo-Caamaño <gpoo@gnome.org>
)

prepare() {
  cd evince
}

build() {
  local meson_options=(
    -D ps=enabled
  )

  # Work around kpathsea build failure with GCC 15
  CFLAGS+=" -DHAVE_STRING_H -DHAVE_STDLIB_H"

  arch-meson evince build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_evince() {
  provides=(libev{document,view}3.so)
  optdepends=('texlive-bin: DVI support')

  meson install -C build --destdir "$pkgdir"

  _pick lib-docs "$pkgdir"/usr/share/doc/lib*
}

package_evince-lib-docs() {
  pkgdesc+=" (library API documentation)"
  depends=()

  mv lib-docs/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: