Name	f2fs-tools
Description	Tools for Flash-Friendly File System (F2FS)
Version	1.16.0-3
Package Base	f2fs-tools
Homepage	https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git/about/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Tobias Powalowski <tpowa@archlinux.org>']
Contributors	['Christian Hesse <mail@eworm.de>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/f2fs-tools
Sources	['git+https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git#tag=v1.16.0']
Dependencies	['util-linux']
Optional-Dependencies	[]
Build-Dependencies	['git']
Provides	['libf2fs.so', 'libf2fs_format.so']
Builddate	23-07-2024 20:10:26
Architecture	x86_64
Distro-Version
Licenses	['GPL']
Hash	46e8c045a8054a891139370b74c875f8fe5360f2c006ec25ab771bf2b8d4e12c

# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Christian Hesse <mail@eworm.de>

pkgname=f2fs-tools
pkgver=1.16.0
pkgrel=3
pkgdesc='Tools for Flash-Friendly File System (F2FS)'
arch=('x86_64')
url='https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git/about/'
provides=('libf2fs.so' 'libf2fs_format.so')
depends=('util-linux')
makedepends=('git')
license=('GPL-2.0-only AND (GPL-2.0-only OR LGPL-2.1-only)')
validpgpkeys=('D3452A79D8C2B4EAC656F4224014A87E824850D2') # Jaegeuk Kim <jaegeuk@kernel.org>
source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git#tag=v${pkgver}")
sha256sums=('87d0ecee953f1c800c8c1869b5cdca8e37d5df1fe7e40a80e21b187425205c48')

_backports=(
  # f2fs-tools: fix build error on lz4-1.9.4
  '19f77c6f6277a274434d6d8883f50e7955c6a8db'
  # f2fs-tools: use stdbool.h instead of bool
  '6617d15a660becc23825007ab3fc2d270b5b250f'
)

_reverts=(
)

prepare() {
  cd "${pkgname}"

  local _c
  for _c in "${_backports[@]}"; do
    if [[ $_c == *..* ]]; then
      git log --oneline --reverse "${_c}"
    else
      git log --oneline -1 "${_c}"
    fi
    git cherry-pick -n -m1 "${_c}"
  done
  for _c in "${_reverts[@]}"; do
    git log --oneline -1 "${_c}"
    git revert -n "${_c}"
  done

  autoreconf -fi
}

build() {
  cd "${pkgname}"

  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin
  make
}

package() {
  cd "${pkgname}"

  make DESTDIR="${pkgdir}/" sbindir=/usr/bin install
}