Name	flex
Description	A tool for generating text-scanning programs
Version	2.6.4-5
Package Base	flex
Homepage	https://github.com/westes/flex
Maintainers	['David Runge <dvzrv@archlinux.org>', 'Lukas Fleischer <lfleischer@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/flex
Sources	['flex-pie.patch', 'https://github.com/westes/flex/releases/download/v2.6.4/flex-2.6.4.tar.gz', 'https://github.com/westes/flex/releases/download/v2.6.4/flex-2.6.4.tar.gz.sig']
Dependencies	['glibc', 'm4', 'sh']
Optional-Dependencies	[]
Build-Dependencies	['help2man']
Provides	[]
Builddate	18-03-2023 00:32:09
Architecture	x86_64
Distro-Version
Licenses	['custom']
Hash	9fdee0b311ce967927006f523e537670d1be94deee52e0115902cf6087c59e25

# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=flex
pkgver=2.6.4
pkgrel=5
pkgdesc="A tool for generating text-scanning programs"
arch=('x86_64')
url="https://github.com/westes/flex"
license=('custom')
depends=('glibc' 'm4' 'sh')
makedepends=('help2man')
source=(
  "https://github.com/westes/flex/releases/download/v$pkgver/flex-$pkgver.tar.gz"{,.sig}
  "flex-pie.patch"
)
sha256sums=('e87aae032bf07c26f85ac0ed3250998c37621d95f8bd748b31f15b33c45ee995'
            'SKIP'
            '20f3cce6b0ea6ab67a902a46b89c292b959994dedcbe6ee5d187f9bba1408b0e')
validpgpkeys=('56C67868E93390AA1039AD1CE4B29C8D64885307') # Will Estes

prepare() {
  cd "$pkgname-$pkgver"
  patch -p1 -i "$srcdir"/flex-pie.patch
  autoreconf -fiv
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  make -k check -C $pkgname-$pkgver
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  ln -s flex "${pkgdir}/usr/bin/lex"

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/license.txt"
}