Name	freetds
Description	Library for accessing Sybase and MS SQL Server databases
Version	1.5.13-1
Package Base	freetds
Homepage	https://www.freetds.org
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/freetds
Sources	['https://www.freetds.org/files/stable/freetds-1.5.13.tar.bz2']
Dependencies	['glibc', 'krb5', 'openssl', 'readline', 'unixodbc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	19-02-2026 18:31:01
Architecture	x86_64
Distro-Version
Licenses	['GPL-2.0-only', 'LGPL-2.0-only']
Hash	59472b993a863372bf51166a351cdccd29dbfd3cea2f4ed375f69da48af16348

# Maintainer:

pkgname=freetds
pkgver=1.5.13
pkgrel=1
pkgdesc='Library for accessing Sybase and MS SQL Server databases'
url='https://www.freetds.org'
arch=(x86_64)
license=(GPL-2.0-only
         LGPL-2.0-only)
depends=(glibc
         krb5
         openssl
         readline
         unixodbc)
backup=(etc/freetds/freetds.conf
        etc/freetds/locales.conf
        etc/freetds/pool.conf)
source=(https://www.freetds.org/files/stable/$pkgname-$pkgver.tar.bz2)
sha256sums=('0c34f60027d714fe11763da14c299d253bbd8c6b8e542a4cdb46f4545f70045d')

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc/freetds \
    --enable-msdblib \
    --enable-krb5 \
    --with-unixodbc=/usr \
    --with-openssl
  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool # Avoid overlinking
  make 
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}