Name	fuse-common
Description	Common files for fuse2/3 packages
Version	3.18.1-1
Package Base	fuse3
Homepage	https://github.com/libfuse/libfuse
Maintainers	['Antonio Rojas <arojas@archlinux.org>']
Contributors	['Mark Rosenstand <mark@archlinux.org>', 'Ronald van Haren <ronald.archlinux.org>', 'Tom Gundersen <teg@jklm.no>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/fuse3
Sources	['https://github.com/libfuse/libfuse/releases/download/fuse-3.18.1/fuse-3.18.1.tar.gz']
Dependencies	[]
Optional-Dependencies	[]
Build-Dependencies	['pkg-config', 'meson', 'udev']
Provides	[]
Builddate	05-01-2026 14:22:47
Architecture	x86_64
Distro-Version
Licenses	['GPL2']
Hash	2cc5c2a5ee60657160f30569e372da2244073122ddcf3a4608273f1bc27144ba

# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Mark Rosenstand <mark@archlinux.org>

pkgbase=fuse3
pkgname=(fuse-common fuse3)
pkgver=3.18.1
pkgrel=1
pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
url='https://github.com/libfuse/libfuse'
arch=('x86_64')
license=('GPL2')
makedepends=('pkg-config' 'meson' 'udev')
options=('!emptydirs')
source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.gz)
sha256sums=('dd395c88f29c7540bbdd0b830260ab8092ccb241bb6e66f603643f715fb9322c')
validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>

build() {
  cd fuse-$pkgver

  rm -rf build
  meson --prefix=/usr --sbindir=bin -D examples=false . build
  cd build
  ninja
}

package_fuse-common() {
  pkgdesc="Common files for fuse2/3 packages"
  backup=(etc/fuse.conf)

  install -Dm644 fuse-${pkgver}/util/fuse.conf "${pkgdir}"/etc/fuse.conf
}

package_fuse3() {
  depends=('fuse-common' 'glibc')

  cd fuse-$pkgver/build

  DESTDIR="${pkgdir}" ninja install

  rm -r "${pkgdir}"/etc/init.d
  rm -r "${pkgdir}"/etc/fuse.conf

  # static device nodes are handled by udev
  rm -r "${pkgdir}"/dev
}