Name	fuse2
Description	Interface for userspace programs to export a filesystem to the Linux kernel
Version	2.9.9-5
Package Base	fuse2
Homepage	https://github.com/libfuse/libfuse
Maintainers	['T.J. Townsend <blakkheim@archlinux.org>']
Contributors	['Mark Rosenstand <mark@archlinux.org>', 'Ronald van Haren <ronald.archlinux.org>', 'Tom Gundersen <teg@jklm.no>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/fuse2
Sources	['conditionally-define-closefrom.patch', 'https://github.com/libfuse/libfuse/releases/download/fuse-2.9.9/fuse-2.9.9.tar.gz', 'https://github.com/libfuse/libfuse/releases/download/fuse-2.9.9/fuse-2.9.9.tar.gz.asc']
Dependencies	['fuse-common', 'glibc']
Optional-Dependencies	[]
Build-Dependencies	['pkg-config']
Provides	['fuse']
Builddate	12-07-2024 17:27:19
Architecture	x86_64
Distro-Version
Licenses	['GPL2']
Hash	fa5b5c88f8c6b27b0fa5384d060c75759acd452cd1e698520969d902e71a1544

# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Mark Rosenstand <mark@archlinux.org>

pkgname=fuse2
pkgver=2.9.9
pkgrel=5
pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
url='https://github.com/libfuse/libfuse'
arch=('x86_64')
license=('GPL2')
depends=('glibc' 'fuse-common')
makedepends=('pkg-config')
provides=(fuse=$pkgver) # TODO: remove it once all packages start to use 'fuse2' name
replaces=('fuse')
conflicts=('fuse')
options=('!emptydirs')
source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.gz{,.asc}
	conditionally-define-closefrom.patch)
sha1sums=('943ba651b14bc4a3c6fd959ed4b8c04f4a59032d'
          'SKIP'
          '90750cd0839c1ee427314241f9ea5f054c3335d8')
sha512sums=('3d82fafd04f2924299bb09d2bb144935fa004a43fb9a6568e2e1cc5a60fded2efa1711029a0d7f12b3e6e4501f7217f2ee3545646d89da8dece083cb390f23e2'
            'SKIP'
            '0836d1693bea203b562a86c992107ee48766f41bb05a31e9af41009d2270ac84d7881aa5bc2a11ed478cd03985876aca5080341ddea701a12a630a36e1b1a80b')
validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>

prepare() {
  cd fuse-$pkgver
  patch -Np1 -i ${srcdir}/conditionally-define-closefrom.patch
  autoreconf -i
}

build() {
  cd fuse-$pkgver

  UDEV_RULES_PATH=/usr/lib/udev/rules.d MOUNT_FUSE_PATH=/usr/bin ./configure --prefix=/usr --libdir=/usr/lib --enable-lib --enable-util --disable-example
  make
}

package() {
  cd fuse-$pkgver

  make DESTDIR="${pkgdir}" install

  # Remove init script in wrong path
  # Don't add our own for now, as fusectl fs oopses on 2.6.18
  rm -r "${pkgdir}"/etc/init.d

  # static device nodes are handled by udev
  rm -r "${pkgdir}"/dev
}