Name	gjs
Description	Javascript Bindings for GNOME
Version	2:1.86.0-1
Package Base	gjs
Homepage	https://wiki.gnome.org/Projects/Gjs
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gjs
Sources	['git+https://gitlab.gnome.org/GNOME/gjs.git#tag=1.86.0', 'git+https://gitlab.gnome.org/GNOME/gobject-introspection-tests.git']
Dependencies	['cairo', 'dconf', 'gcc-libs', 'glib2', 'glibc', 'gobject-introspection-runtime', 'js140', 'libffi', 'libreadline.so', 'libsysprof-capture', 'libx11', 'readline']
Optional-Dependencies	[]
Build-Dependencies	['dbus', 'git', 'gobject-introspection', 'meson']
Provides	['libgjs.so']
Builddate	17-09-2025 19:23:55
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.0-or-later']
Hash	54d396b367ad06eba8358b4318871842322a3c6b67696b9a4398e46098a1d49e

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=gjs
pkgver=1.86.0
pkgrel=1
epoch=2
pkgdesc="Javascript Bindings for GNOME"
url="https://wiki.gnome.org/Projects/Gjs"
arch=(x86_64)
license=(LGPL-2.0-or-later)
depends=(
  cairo
  dconf
  gcc-libs
  glib2
  glibc
  gobject-introspection-runtime
  js140
  libffi
  libsysprof-capture
  libx11
  readline
)
makedepends=(
  dbus
  git
  gobject-introspection
  meson
)
checkdepends=(
  gtk3
  gtk4
  xorg-server-xvfb
)
provides=(libgjs.so)
source=("git+https://gitlab.gnome.org/GNOME/gjs.git#tag=$pkgver"
        "git+https://gitlab.gnome.org/GNOME/gobject-introspection-tests.git")
b2sums=('c4875a14a5c0c2edf70f469af90a938baf87740b8a1d542cc2d3640e802efa420d7ecff2a807ca80b7bd4e65da0e393f7a9b708b653f906e77460671ebe3e8b4'
        'SKIP')
validpgpkeys=(
  53C0524AD3AE115F69C47D2D0E9D857756977391 # Philip Chimento (Signing Key for GNOME Releases) <philip.chimento@gmail.com>
)

prepare() {
  cd gjs

  git submodule init
  git submodule set-url subprojects/gobject-introspection-tests "${srcdir}/gobject-introspection-tests"
  git -c protocol.file.allow=always -c protocol.allow=never submodule update
}

build() {
  local meson_options=(
    -D installed_tests=false
  )

  arch-meson gjs build "${meson_options[@]}"
  meson compile -C build
}

check() {
  dbus-run-session xvfb-run -s '-nolisten local' \
    meson test -C build --print-errorlogs ||:
}

package() {
  depends+=(libreadline.so)
  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et: