Name	glslang
Description	OpenGL and OpenGL ES shader front end and validator
Version	1:1.4.341.0-1
Package Base	glslang
Homepage	https://github.com/KhronosGroup/glslang
Maintainers	['Daurnimator <daurnimator@archlinux.org>', 'Robin Candau <antiz@archlinux.org>', 'Sven-Hendrik Haase <svenstaro@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/glslang
Sources	['git+https://github.com/KhronosGroup/glslang.git#tag=vulkan-sdk-1.4.341.0']
Dependencies	['gcc-libs', 'spirv-tools']
Optional-Dependencies	[]
Build-Dependencies	['cmake', 'ninja', 'spirv-headers', 'python', 'git']
Provides	[]
Builddate	03-02-2026 10:29:33
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	584390193e86ff9152d807eabcaf176461907fd0ca9c95f51634448790d22288

# Maintainer: Daurnimator <daurnimator@archlinux.org>
# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
# Maintainer: Robin Candau <antiz@archlinux.org>

pkgname=glslang
pkgver=1.4.341.0
pkgrel=2
epoch=1
pkgdesc="OpenGL and OpenGL ES shader front end and validator"
url="https://github.com/KhronosGroup/glslang"
arch=('x86_64')
license=('BSD-3-Clause')
depends=('glibc' 'libstdc++' 'spirv-tools')
makedepends=('cmake' 'ninja' 'spirv-headers' 'python' 'git')
options=('staticlibs')
source=("git+${url}.git#tag=vulkan-sdk-${pkgver}")
sha256sums=('bf7d224dc960f044884d9ca2285d0df56b618a76c501eee0bc24d10c40cf2c38')

build() {
  cd "${pkgname}"

  # we need fat LTO objects to not break consumers during linking
  CXXFLAGS+=" -ffat-lto-objects"
  cmake \
    -Bbuild-static \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_BUILD_TYPE='None' \
    -DALLOW_EXTERNAL_SPIRV_TOOLS='ON' \
    -DBUILD_SHARED_LIBS='OFF'
  cmake --build build-static

  cmake \
    -Bbuild-shared \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_BUILD_TYPE='None' \
    -DALLOW_EXTERNAL_SPIRV_TOOLS='ON' \
    -DBUILD_SHARED_LIBS='ON' \
    -DGLSLANG_TESTS='ON'
  cmake --build build-shared
}

check() {
  cd "${pkgname}"

  ninja -Cbuild-shared test
}

package() {
  cd "${pkgname}"

  DESTDIR="${pkgdir}" cmake --install build-static
  DESTDIR="${pkgdir}" cmake --install build-shared

  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  cd "${pkgdir}/usr/lib"
  for lib in *.so; do
    ln -sf "${lib}" "${lib}.0"
  done
}

# vim: ts=2 sw=2 et: