Name	glu
Description	Mesa OpenGL utility library
Version	9.0.3-3
Package Base	glu
Homepage	https://gitlab.freedesktop.org/mesa/glu
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Laurent Carlier <lordheavym@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/glu
Sources	['https://mesa.freedesktop.org/archive/glu/glu-9.0.3.tar.xz', 'https://mesa.freedesktop.org/archive/glu/glu-9.0.3.tar.xz.sig']
Dependencies	['glibc', 'libgcc', 'libgl', 'libstdc++']
Optional-Dependencies	[]
Build-Dependencies	['meson']
Provides	[]
Builddate	14-02-2026 11:08:29
Architecture	x86_64
Distro-Version
Licenses	['MIT', 'SGI-B-2.0']
Hash	a981608b5a1c7d6cdee0e71385035dc45ada61dc1221429adde16909e17222e6

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Laurent Carlier <lordheavym@gmail.com>

pkgname=glu
pkgver=9.0.3
pkgrel=3
pkgdesc="Mesa OpenGL utility library"
arch=('x86_64')
url="https://gitlab.freedesktop.org/mesa/glu"
# no license file included, can be found inside the source files
license=('SGI-B-2.0' 'MIT')
depends=('libgl' 'glibc' 'libstdc++' 'libgcc')
makedepends=('meson')
source=(https://mesa.freedesktop.org/archive/glu/glu-$pkgver.tar.xz{,.sig})
sha512sums=('b2781059c0e176192c3fc0d7244645020937a463311171efddb9f35fb94ee43faabcf627fa7f429d48fceaf6dd9c5adb69c86c7a21ec4ea490f4ab143d52e3ba'
            'SKIP')
#validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # "Matt Turner <mattst88@gmail.com>"
validpgpkeys=('57551DE15B968F6341C248F68D8E31AFC32428A6') # Eric Engestrom <eric@engestrom.ch>

build() {
  arch-meson glu-$pkgver build \
    -D default_library=shared

  # Print config
  meson configure build

  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  # no license included
  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
  echo "SGI-B-2.0 and MIT" > "${pkgdir}/usr/share/licenses/${pkgname}"/LICENSE
}