Name	gnome-characters
Description	A character map application
Version	49.1-1
Package Base	gnome-characters
Homepage	https://apps.gnome.org/Characters/
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gnome-characters
Sources	['git+https://gitlab.gnome.org/GNOME/gnome-characters.git#tag=49.1']
Dependencies	['dconf', 'emoji-font', 'gjs', 'glib2', 'glibc', 'gnome-desktop-4', 'gtk4', 'hicolor-icon-theme', 'libadwaita']
Optional-Dependencies	[]
Build-Dependencies	['appstream', 'git', 'glib2-devel', 'gobject-introspection', 'gperf', 'meson']
Provides	[]
Builddate	12-10-2025 17:39:05
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause AND GPL-2.0-or-later']
Hash	17b13fbd99ee4ab58de66f3ac57ad469c2092ccdc8bfc55e0fd0c7212ca7c17f

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-characters
pkgver=49.1
pkgrel=1
pkgdesc="A character map application"
url="https://apps.gnome.org/Characters/"
arch=(x86_64)
license=("BSD-3-Clause AND GPL-2.0-or-later")
depends=(
  dconf
  emoji-font
  gjs
  glib2
  glibc
  gnome-desktop-4
  gtk4
  hicolor-icon-theme
  libadwaita
)
makedepends=(
  appstream
  git
  glib2-devel
  gobject-introspection
  gperf
  meson
)
checkdepends=(weston)
groups=(gnome)
source=("git+https://gitlab.gnome.org/GNOME/gnome-characters.git#tag=${pkgver/[a-z]/.&}")
b2sums=('5e3ca9748d7edfcfb50a73f9b68724af4dc63264db2a1a5a7e370129f325eb55a00d359b843ae423cd92722d3b76d950d0b68828b94900ca90b1043c2b1caef7')

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() (
  export XDG_RUNTIME_DIR="$PWD/runtime-dir"
  mkdir -p -m 700 "$XDG_RUNTIME_DIR"

  export WAYLAND_DISPLAY=wayland-5
  weston --backend=headless-backend.so --socket=$WAYLAND_DISPLAY --idle-time=0 &
  _w=$!

  trap "kill $_w; wait" EXIT

  meson test -C build --print-errorlogs
)

package() {
  meson install -C build --destdir "$pkgdir"
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
}

# vim:set sw=2 sts=-1 et: