Name	gnutls
Description	A library which provides a secure layer over a reliable transport layer
Version	3.8.12-2
Package Base	gnutls
Homepage	https://www.gnutls.org/
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Jan de Groot <jgc@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gnutls
Sources	['config', 'https://www.gnupg.org/ftp/gcrypt/gnutls/v3.8/gnutls-3.8.12.tar.xz', 'https://www.gnupg.org/ftp/gcrypt/gnutls/v3.8/gnutls-3.8.12.tar.xz.sig']
Dependencies	['brotli', 'glibc', 'gmp', 'leancrypto', 'libgcc', 'libidn2', 'libidn2.so', 'libp11-kit', 'libstdc++', 'libtasn1', 'libunistring', 'nettle', 'zlib', 'zstd']
Optional-Dependencies	['tpm2-tss']
Build-Dependencies	['tpm2-tss', 'gtk-doc']
Provides	[]
Builddate	14-02-2026 13:41:01
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-or-later AND LGPL-2.1-or-later']
Hash	5abcbe1d5b9136fded7f3ba4c060c0c2c8f28604c2f824e7bc9db853095ccf16

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnutls
pkgver=3.8.12
pkgrel=2
pkgdesc="A library which provides a secure layer over a reliable transport layer"
arch=('x86_64')
license=('GPL-3.0-or-later AND LGPL-2.1-or-later')
url="https://www.gnutls.org/"
options=('!zipman')
depends=('glibc' 'gmp' 'libtasn1' 'zlib' 'nettle' 'leancrypto' 'libstdc++' 'libgcc'
         'libp11-kit' 'libidn2' 'zstd' 'libidn2.so' 'libunistring' 'brotli')
makedepends=('tpm2-tss'
            # required for autoreconf when patching
            'gtk-doc')
checkdepends=('net-tools' 'tpm2-tools')
optdepends=('tpm2-tss: support for TPM2 wrapped keys')
backup=(etc/gnutls/config
        # etc/modules-load.d/gnutls.conf
)
source=(https://www.gnupg.org/ftp/gcrypt/gnutls/v3.8/${pkgname}-${pkgver}.tar.xz{,.sig}
        config)
sha256sums=('a7b341421bfd459acf7a374ca4af3b9e06608dcd7bd792b2bf470bea012b8e51'
            'SKIP'
            '22e614510fe52defe8c233ce3e5ead2205739fd967657ce3176ca121f3c562b5')
# validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # "Daiki Ueno <ueno@unixuser.org>"
validpgpkeys=('5D46CB0F763405A7053556F47A75A648B3F9220C') # "Zoltan Fridrich <zfridric@redhat.com>"

prepare() {
  cd ${pkgname}-${pkgver}
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --disable-static \
    --with-idn \
    --with-brotli \
    --with-zstd \
    --with-tpm2 \
    --enable-openssl-compatibility \
    --with-default-trust-store-pkcs11="pkcs11:" \
    --enable-ktls \
    --with-leancrypto
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # prepare to load tls module required for ktls
  # install -dm755 "$pkgdir"/etc/modules-load.d
  # echo "#tls" > "$pkgdir"/etc/modules-load.d/gnutls.conf

  # disable ktls by default for now
  install -dm755 "$pkgdir"/etc/gnutls
  install -Dm644 "${srcdir}"/config  "$pkgdir"/etc/gnutls/config
}