Name	gperftools
Description	Fast, multi-threaded malloc and nifty performance analysis tools
Version	2.17.2-1
Package Base	gperftools
Homepage	https://github.com/gperftools/gperftools
Maintainers	['Balló György <ballogyor+arch@gmail.com>', 'Balló György <bgyorgy@archlinux.org>']
Contributors	['Alexander Rødseth <rodseth@gmail.com>', 'Dave Reisner <dreisner@archlinux.org>', 'JaDa <jada@archlinux.us>', 'Jan Rüegg <rggjan@gmail.com>', 'Joaquim Pedro <osmano807@gmail.com>', 'Thomas Jost <schnouki@schnouki.net>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gperftools
Sources	['git+https://github.com/gperftools/gperftools.git#tag=gperftools-2.17.2']
Dependencies	['gcc-libs', 'glibc', 'libunwind']
Optional-Dependencies	[]
Build-Dependencies	['asciidoctor', 'git']
Provides	[]
Builddate	02-09-2025 11:25:14
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	4eb93f7ad06343a47d8abc65bfcb528e86714a07e61e789777b71fade31166d5

# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
# Contributor: JaDa <jada@archlinux.us>
# Contributor: Joaquim Pedro <osmano807@gmail.com>
# Contributor: Jan Rüegg <rggjan@gmail.com>

pkgname=gperftools
pkgver=2.17.2
pkgrel=1
pkgdesc='Fast, multi-threaded malloc and nifty performance analysis tools'
arch=(x86_64)
url='https://github.com/gperftools/gperftools'
license=(BSD-3-Clause)
depends=(
  gcc-libs
  glibc
  libunwind
)
makedepends=(
  asciidoctor
  git
)
source=("git+https://github.com/gperftools/gperftools.git#tag=$pkgname-$pkgver")
b2sums=(5ae15f6d12150351bc12d462905840a816bfbec8e81ce42e589cfc7e79aeeebb460d68e12aa2fce7f73e7148d03f92b0f3cf47fdf104f2434b4c7bfa89d78ddc)

prepare() {
  cd $pkgname
  autoreconf -fi
}

build() {
  cd $pkgname
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-frame-pointers \
    --enable-libunwind
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYING
}