Name	gsm
Description	Shared libraries for GSM 06.10 lossy speech compression
Version	1.0.23-1
Package Base	gsm
Homepage	https://www.quut.com/gsm/
Maintainers	['Antonio Rojas <arojas@archlinux.org>', 'Jan de Groot <jgc@archlinux.org>']
Contributors	['Darwin Bautista <djclue917@gmail.com>', 'Maxime de Roucy <maxime.deroucy@gmail.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gsm
Sources	['gsm-fix-toast-install.patch', 'gsm-shared.patch', 'https://www.quut.com/gsm/gsm-1.0.23.tar.gz']
Dependencies	['glibc']
Optional-Dependencies	[]
Build-Dependencies	[]
Provides	[]
Builddate	21-11-2025 21:22:53
Architecture	x86_64
Distro-Version
Licenses	['custom']
Hash	af9fc6060e907fc7480c51cebd9212c44bd903753d438474f1fdf37147459369

# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Maxime de Roucy <maxime.deroucy@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>

pkgname=gsm
pkgver=1.0.23
pkgrel=1
pkgdesc="Shared libraries for GSM 06.10 lossy speech compression"
arch=('x86_64')
url="https://www.quut.com/gsm/"
license=('custom')
depends=('glibc')
source=("https://www.quut.com/$pkgname/$pkgname-$pkgver.tar.gz" gsm-shared.patch gsm-fix-toast-install.patch)
sha512sums=('96a477f7f4a2ad8319d97c4010e3e2ddb453fa6eda44dac83a62f060a3e6790cc0298d3f402eab52e1a7c0f5c001ab793baefd1fc876ff6432efeb506981bdd8'
            '5833f9157ab5adf68b3ad0b6316ec563389fe39dd7b99ee04acc08a32bfccf9f517b9289ce3bfd32e191ab8a4b674c08ea1fbba9411e43c0d44f78f24bf885cd'
            '88f3214e92d4f5b9dae9c5d67073abb36c7889cdcb90a00fb023794ae474c0560d8ea5098ce3e5424a1021fe44cd4f6b91d86c77e4b864fe97b51d69debf0c5d')

prepare() {
  cd $pkgname-${pkgver%.*}-pl${pkgver##*.}

  patch -p0 -i ../gsm-shared.patch
  patch -p0 -i ../gsm-fix-toast-install.patch
}

build() {
  cd $pkgname-${pkgver%.*}-pl${pkgver##*.}

  make CCFLAGS="-c ${CFLAGS} -fPIC"
}

package() {
  cd $pkgname-${pkgver%.*}-pl${pkgver##*.}

  # Prepare directories
  install -m755 -d "$pkgdir"/usr/{bin,lib,include/gsm,share/{licenses/$pkgname,man/man{1,3}}}

  make -j1 INSTALL_ROOT="$pkgdir"/usr \
    GSM_INSTALL_INC="$pkgdir"/usr/include/gsm \
    GSM_INSTALL_MAN="$pkgdir"/usr/share/man/man3 \
    TOAST_INSTALL_MAN="$pkgdir"/usr/share/man/man1 \
    install

  # Install license
  install -m644 COPYRIGHT "$pkgdir"/usr/share/licenses/$pkgname/license.txt
}