Name	gtest
Description	Google Test - C++ testing utility
Version	1.17.0-2
Package Base	gtest
Homepage	https://github.com/google/googletest
Maintainers	['Carl Smedstad <carsme@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Alexandre Bique <bique.alexandre@gmail.com>', 'Cody Maloney <cmaloney@theoreticalchaos.com>', 'Felix Yan <felixonmars@archlinux.org>', 'Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>', 'Louis R. Marascio <lrm@fitnr.com>', 'acxz <akashpatel2008@yahoo.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gtest
Sources	['googletest-1.17.0.tar.gz::https://github.com/google/googletest/archive/v1.17.0.tar.gz']
Dependencies	['glibc', 'libgcc', 'libstdc++']
Optional-Dependencies	['python']
Build-Dependencies	['cmake', 'python']
Provides	['gmock', 'libgmock.so', 'libgmock_main.so', 'libgtest.so', 'libgtest_main.so']
Builddate	14-02-2026 23:33:40
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	fe0603bf90c88de529881dafa5e348259ed663da4c680c5025efb11edd17e943

# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Alexandre Bique <bique.alexandre@gmail.com>
# Contributor: Louis R. Marascio <lrm@fitnr.com>
# Contributor: Cody Maloney <cmaloney@theoreticalchaos.com>
# Contributor: acxz <akashpatel2008 at yahoo dot com>

pkgname=gtest
pkgver=1.17.0
pkgrel=2
pkgdesc='Google Test - C++ testing utility'
arch=('x86_64')
url='https://github.com/google/googletest'
license=('BSD-3-Clause')
depends=(
  'glibc'
  'libgcc'
  'libstdc++'
)
makedepends=(
  'cmake'
  'python'
)
optdepends=('python: gmock generator')
conflicts=('gmock')
replaces=('gmock')
provides=(
  'gmock'
  'libgmock.so'
  'libgmock_main.so'
  'libgtest.so'
  'libgtest_main.so'
)
_srcname=googletest-${pkgver}
source=("${_srcname}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha512sums=('0f57e9ef06925e5b7722df1eb92ef5850e8dce79220ea16a8aaff586a71c0b01460ef1713649ee24ffedb2e6ad5a51e9198c5a5ae1b2789e43feb1f494e7d45c')

build() {
 cmake -H${_srcname} -Bbuild \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=None \
    -Wno-dev \
    -DBUILD_SHARED_LIBS=ON \
    -Dgtest_build_tests=ON \
    -DGOOGLETEST_VERSION=$pkgver
  cmake --build build
}

check() {
  cmake --build build --target test
}

package() {
  DESTDIR="${pkgdir}" cmake --install build

  cd ${_srcname}
  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -vDm 644 README.md CONTRIBUTORS -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et: