Name	gtksourceview5
Description	A text widget adding syntax highlighting and more to GNOME
Version	5.18.0-1
Package Base	gtksourceview5
Homepage	https://wiki.gnome.org/Projects/GtkSourceView
Maintainers	['Fabian Bornschein <fabiscafe@archlinux.org>', 'Jan Alexander Steffens (heftig) <heftig@archlinux.org>']
Contributors	['Balló György <ballogyor+arch@gmail.com>', 'Ionut Biru <ibiru@archlinux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gtksourceview5
Sources	['git+https://gitlab.gnome.org/GNOME/gtksourceview.git#tag=5.18.0']
Dependencies	['cairo', 'fontconfig', 'fribidi', 'gdk-pixbuf2', 'glib2', 'glibc', 'gtk4', 'hicolor-icon-theme', 'libxml2', 'pango', 'pcre2']
Optional-Dependencies	[]
Build-Dependencies	['gi-docgen', 'git', 'glib2-devel', 'gobject-introspection', 'meson', 'vala']
Provides	['libgtksourceview-5.so']
Builddate	13-09-2025 21:55:35
Architecture	x86_64
Distro-Version
Licenses	['LGPL-2.1-or-later']
Hash	dfcc16ef47995a3b4c614ed0bb99a8e82577a222bd309c5e2e28784c53559758

# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=gtksourceview5
pkgname=(
  gtksourceview5
  gtksourceview5-docs
)
pkgver=5.18.0
pkgrel=1
pkgdesc="A text widget adding syntax highlighting and more to GNOME"
url="https://wiki.gnome.org/Projects/GtkSourceView"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  cairo
  fontconfig
  fribidi
  gdk-pixbuf2
  glib2
  glibc
  gtk4
  hicolor-icon-theme
  libxml2
  pango
  pcre2
)
makedepends=(
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  vala
)
checkdepends=(xorg-server-xvfb)
source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#tag=$pkgver")
b2sums=('ffda1317abeff5aa4db02f632d0cbae8c70d296e6fc370d40f35176ef1f9c65ebc9a2fa39ceb5660826a002ae40bed9b68f81198e24fd4617a3bffbbcef51361')

prepare() {
  cd gtksourceview
}

build() {
  arch-meson gtksourceview build -D documentation=true
  meson compile -C build
}

check() {
  GTK_A11Y=none dbus-run-session xvfb-run -s '-nolisten local' \
    meson test -C build --print-errorlogs
}

package_gtksourceview5() {
  provides=(libgtksourceview-${pkgver%%.*}.so)

  meson install -C build --destdir "$pkgdir"

  mkdir -p doc/usr/share
  mv {"$pkgdir",doc}/usr/share/doc
}

package_gtksourceview5-docs() {
  pkgdesc+=" (documentation)"
  depends=()

  mv doc/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et: