Name	guile
Description	Portable, embeddable Scheme implementation written in C
Version	3.0.11-1
Package Base	guile
Homepage	https://www.gnu.org/software/guile/
Maintainers	['Frederik Schwan <freswa@archlinux.org>']
Contributors	['Bartłomiej Piotrowski <bpiotrowski@archlinux.org>', 'Jan de Groot <jgc@archlinux.org>', 'Tom Newsom <Jeepster@gmx.co.uk>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/guile
Sources	['https://ftp.gnu.org/pub/gnu/guile/guile-3.0.11.tar.gz', 'https://ftp.gnu.org/pub/gnu/guile/guile-3.0.11.tar.gz.sig']
Dependencies	['gc', 'gmp', 'libffi', 'libunistring', 'libxcrypt', 'ncurses']
Optional-Dependencies	[]
Build-Dependencies	['texinfo']
Provides	[]
Builddate	01-12-2025 22:24:56
Architecture	x86_64
Distro-Version
Licenses	['GPL']
Hash	dbc4c775e0474a5ac8784aab95a77f6fd23ebc930abea34c7a5e0f83dd00873d

# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=guile
pkgver=3.0.11
pkgrel=1
pkgdesc='Portable, embeddable Scheme implementation written in C'
url='https://www.gnu.org/software/guile/'
arch=(x86_64)
license=(GPL)
depends=(gmp ncurses libunistring gc libffi libxcrypt)
makedepends=(texinfo)
source=(https://ftp.gnu.org/pub/gnu/$pkgname/$pkgname-$pkgver.tar.gz{,.sig})
validpgpkeys=('3CE464558A84FDC69DB40CFB090B11993D9AEBB5' # Ludovic Courtès <ludo@gnu.org>
              'FF478FB264DE32EC296725A3DDC0F5358812F8F2' # Andy Wingo
              '4FD4D288D445934E0A14F9A5A8803732E4436885') # Andy Wingo <wingo@pobox.com>"
sha256sums=('3c9c16972a73bb792752f2e4f1cce7212d7638d5494b5f7e8e19f3819dbf3a19'
            'SKIP')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --disable-static  \
    --disable-error-on-warning
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
  rm "$pkgdir"/usr/lib/libguile-3.?.so.*-gdb.scm
}