Name	gzip
Description	GNU compression utility
Version	1.14-2
Package Base	gzip
Homepage	https://www.gnu.org/software/gzip/
Maintainers	['Christian Hesse <eworm@archlinux.org>', 'Sébastien "Seblu" Luttringer <seblu@archlinux.org>']
Contributors	['Allan McRae <allan@archlinux.org>', 'judd <jvinet@zeroflux.org>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/gzip
Sources	['git+https://git.savannah.gnu.org/git/gnulib.git', 'git+https://git.savannah.gnu.org/git/gzip.git#tag=v1.14?signed']
Dependencies	['bash', 'coreutils', 'glibc', 'grep', 'sed']
Optional-Dependencies	['diffutils', 'less', 'util-linux']
Build-Dependencies	['git', 'less', 'python', 'wget']
Provides	[]
Builddate	26-04-2025 23:58:54
Architecture	x86_64
Distro-Version
Licenses	['GPL-3.0-or-later']
Hash	e08b33c6aa9a19108d7941a78a6d137e3f700a544d21f14bf863d3c392c3a88e

# Maintainer: Sébastien "Seblu" Luttringer <seblu@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=gzip
pkgver=1.14
pkgrel=2
pkgdesc='GNU compression utility'
arch=('x86_64')
url='https://www.gnu.org/software/gzip/'
license=('GPL-3.0-or-later')
depends=('glibc' 'sh' 'coreutils' 'sed')
makedepends=('git' 'less' 'python' 'wget')
optdepends=('diffutils: zdiff/zcmp support'
            'grep: zegrep/zfgrep/zforce/zgrep support'
            'less: zless support'
            'util-linux: zmore support')
validpgpkeys=('155D3FC500C834486D1EEA677FD9FCCB000BEEEE') # Jim Meyering
source=("git+https://git.savannah.gnu.org/git/gzip.git#tag=v${pkgver}?signed"
        "git+https://git.savannah.gnu.org/git/gnulib.git")
sha256sums=('b1c2422ee156ef11e9601d2651f8543dd71f941887cd407fe23584ab95417c93'
            'SKIP')

prepare() {
  cd $pkgname

  git submodule init
  git config submodule.gnulib.url "${srcdir}/gnulib"
  git -c protocol.file.allow=always submodule update

  ./bootstrap
}

build() {
  cd $pkgname
  ./configure \
    --prefix=/usr \
    --disable-gcc-warnings
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make prefix="$pkgdir/usr" install
}