Name	hwloc
Description	Portable Hardware Locality is a portable abstraction of hierarchical architectures
Version	2.13.0-1
Package Base	hwloc
Homepage	https://www.open-mpi.org/projects/hwloc/
Maintainers	['Carl Smedstad <carsme@archlinux.org>', 'Levente Polyak <anthraxx[at]archlinux[dot]org>']
Contributors	['Hervé YVIQUEL <elldekaa@gmail.com>', 'Stéphane Gaudreault <stephane@archlinux.org>', 'Sylvain HENRY <hsyl20@yahoo.fr>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/hwloc
Sources	['https://www.open-mpi.org/software/hwloc/v2.13/downloads/hwloc-2.13.0.tar.bz2']
Dependencies	['glibc', 'libpciaccess', 'libtool', 'ncurses', 'systemd-libs']
Optional-Dependencies	['cairo', 'libxml2']
Build-Dependencies	['cairo', 'libx11', 'libxml2', 'systemd']
Provides	[]
Builddate	09-02-2026 19:11:33
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause']
Hash	1afdfb08499a606fe0b5d746be7b046c4e0c2e73a9d5141370c31262fb97c739

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Sylvain HENRY <hsyl20@yahoo.fr>
# Contributor: Hervé YVIQUEL <elldekaa@gmail.com>

pkgname=hwloc
pkgver=2.13.0
pkgrel=1
pkgdesc='Portable Hardware Locality is a portable abstraction of hierarchical architectures'
url='https://www.open-mpi.org/projects/hwloc/'
arch=('x86_64')
license=('BSD-3-Clause')
depends=(
  'glibc'
  'libpciaccess'
  'libtool'
  'ncurses'
  'systemd-libs'
)
makedepends=(
  'cairo'
  'libx11'
  'libxml2'
  'systemd'
)
optdepends=(
  'cairo: PDF, Postscript, and PNG export support'
  'libxml2: full XML import/export support'
)
options=('!docs')
source=("https://www.open-mpi.org/software/hwloc/v${pkgver%.*}/downloads/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('88958a624211fbc3fd2f424de8eed2d6b47a0e3b3cf524725c9695d8a73929de71f3615d4f2e610678a8e1b169c7a592eae45464493f6288b16b0ce368015b28')
b2sums=('4c92526d67fb075ee46b36b921dacc0e07e4fc967e2542c3a21ba541a278469d9f6b1dcc0a8592ebb96ba546d5f31aee37acb22b6b560dff7a3bced444ad5582')

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --enable-plugins \
    --sysconfdir=/etc
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: