Name	icu
Description	International Components for Unicode library
Version	78.2-2
Package Base	icu
Homepage	https://icu.unicode.org
Maintainers	['Andreas Radke <andyrtr@archlinux.org>']
Contributors	['Art Gramlich <art@gramlich-net.com>']
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/icu
Sources	['ICU-22132.patch', 'https://github.com/unicode-org/icu/releases/download/release-78.2/icu4c-78.2-sources.tgz', 'https://github.com/unicode-org/icu/releases/download/release-78.2/icu4c-78.2-sources.tgz.asc']
Dependencies	['glibc', 'libgcc', 'libstdc++', 'sh']
Optional-Dependencies	[]
Build-Dependencies	['python']
Provides	['libicudata.so', 'libicui18n.so', 'libicuio.so', 'libicutest.so', 'libicutu.so', 'libicuuc.so']
Builddate	14-02-2026 13:53:57
Architecture	x86_64
Distro-Version
Licenses	['BSD-2-Clause', 'BSD-3-Clause', 'LicenseRef-Unicode-3.0', 'NAIST-2003']
Hash	b8b74816d2bda0727f43757ac9806086036a28de7a07cfc2a6e998bb9beb53b3

# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Art Gramlich <art@gramlich-net.com>

pkgname=icu
pkgver=78.2
pkgrel=2
pkgdesc="International Components for Unicode library"
arch=(x86_64)
url="https://icu.unicode.org"
license=('LicenseRef-Unicode-3.0'
         'BSD-2-Clause'
         'BSD-3-Clause'
         'NAIST-2003')
depends=('glibc' 'libstdc++' 'libgcc' 'sh')
makedepends=('python')
provides=(libicu{data,i18n,io,test,tu,uc}.so)
source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver}/icu4c-${pkgver}-sources.tgz{,.asc}
        ICU-22132.patch)
# https://github.com/unicode-org/icu/releases/download/release-78.1/SHASUM512.txt
sha512sums=('92feddfe81c57336f386c7cbc9f6d976bf349db148a77a247c4559676f51116115c8c52c4d907feb50933f72ab75fd8e48be092bf9c8ca33a3e8fabc9372a5d6'
            'SKIP'
            '1178062ccfcf7ecc698c64132b3612e73f9c4b0bbfaa668ae2039f3eb4cb2722d0b08a9f45b057da10def7a308d5c8d14c0c644892e7f11092c9cc488c850ab7')
validpgpkeys=('E52F07877A5805F9AF4AB0ACD46C5610D06E7001') # ICU Release Robot <icu-robot@unicode.org>

prepare() {
  cd icu/source
  # Required fix for thunderbird 115 to show Calendar and sidebar properly
  # https://bugzilla.mozilla.org/show_bug.cgi?id=1843007
  # https://unicode-org.atlassian.net/browse/ICU-22132
  # patch -Np1 < "../../ICU-22132.patch"
}

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

check() {
  cd icu/source
  make check
}

package() {
  cd icu/source
  make DESTDIR="${pkgdir}" install

  # Install license
  install -Dm644 ../LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}