Name	intel-media-driver
Description	Intel Media Driver for VAAPI — Broadwell+ iGPUs
Version	25.3.4-2
Package Base	intel-media-driver
Homepage	https://github.com/intel/media-driver/
Maintainers	['Bruno Pagani <archange@archlinux.org>', 'Daniel Bermond <dbermond@archlinux.org>']
Contributors	[]
Distro-repo	https://gitlab.archlinux.org/archlinux/packaging/packages/intel-media-driver
Sources	['https://github.com/intel/media-driver/archive/intel-media-25.3.4/intel-media-driver-25.3.4.tar.gz']
Dependencies	['glibc', 'intel-gmmlib', 'libgcc', 'libstdc++', 'libva']
Optional-Dependencies	[]
Build-Dependencies	['cmake']
Provides	[]
Builddate	15-02-2026 15:27:52
Architecture	x86_64
Distro-Version
Licenses	['BSD-3-Clause', 'MIT']
Hash	e029c2c6688f5a26d3cd3d95203617a8741d1c20ed56bfc14a5eb27a44122e3d

# Maintainer: Bruno Pagani <archange@archlinux.org>
# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=intel-media-driver
pkgver=25.3.4
pkgrel=2
pkgdesc='Intel Media Driver for VAAPI — Broadwell+ iGPUs'
arch=('x86_64')
url='https://github.com/intel/media-driver/'
license=('BSD-3-Clause' 'MIT')
depends=(
    'glibc'
    'intel-gmmlib'
    'libgcc'
    'libstdc++'
    'libva')
makedepends=(
    'cmake')
source=("https://github.com/intel/media-driver/archive/intel-media-${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('ef9a7a0881b250d23df7d4676341a3729b28887bcf404a74d48db5f44ffa0220')

build() {
    cmake -B build -S "media-driver-intel-media-${pkgver}" \
        -G 'Unix Makefiles' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DCMAKE_INSTALL_LIBDIR:PATH='lib' \
        -DCMAKE_POLICY_VERSION_MINIMUM:STRING='3.5.0' \
        -DINSTALL_DRIVER_SYSCONF:BOOL='OFF' \
        -DMEDIA_BUILD_FATAL_WARNINGS:BOOL='OFF' \
        -Wno-dev
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -D -m644 "media-driver-intel-media-${pkgver}/LICENSE.md" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}